Upload New File

=csas6-shift

htgr pebble

v7.1-252

' ==============================

'   Compositions

' ==============================

read comp

' ================

'   fuel pebble

' ================

' fuel

uo2         10 den=10.4 1.0 293.0 92234 0.051 92235 9.6 92238 90.349 end

' first coating

c-graphite  11 den=1.05 1.0    293.0  end

' inner pyro carbon

c-graphite  12 den=1.90 1.0    293.0  end

' silicon carbide

ATOMSiC     13 3.18 2  6000 1 14000 1  1.0  293.0  end

' outer pyro carbon

c-graphite  14 den=1.90 1.0    293.0  end

' graphite matrix

c-graphite  15 den=1.74 1.0    293.0  end

' fuel-free graphite layer

c-graphite  16 den=1.74 1.0    293.0  end

' helium around pebble

he          17  0 8.431E-4     293.0 end

end comp   

' ==============================

'   Celldata for self-shielding

' ==============================

read celldata

doublehet right_bdy=white fuelmix=99 end

  gfr=0.025     10

  coatr=0.0345  11

  coatr=0.0385  12

  coatr=0.0420  13

  coatr=0.0460  14

  matrix=15 numpar=15000 end grain

  pebble sphsquarep right_bdy=white left_bdy=reflected

  hpitch=3.0 17 fuelr=2.5 cladr=3.0 16 fuelh=6.0 end

end celldata

' ==============================

'   Neutron transport settings

' ==============================

read parm

 npg=2000 gen=100 nsk=20

 htm=no plt=no

end parm

' ==============================

'   Boundary condition

' ==============================

read bounds

' reflective boundary condition in all direction

 all=mirror

end bounds

' ==============================

'   Geometry

' ==============================

read geometry

' ====================

'   TRISO particle

' ====================

unit 1 com="TRISO"

  sphere 1 0.025

  sphere 2 0.0345

  sphere 3 0.0385

  sphere 4 0.0420

  sphere 5 0.0460

  media 10 1 1

  media 11 1 2 -1

  media 12 1 3 -2

  media 13 1 4 -3

  media 14 1 5 -4

  boundary 5

' ====================

'   fuel pebble

' ====================

global unit 10

 sphere 10 2.5

 sphere 11 3.0

 cuboid 12 6p3.0

 media 99 1 10

 media 16 1 11 -10

 media 17 1 12 -11

boundary 12

end geometry

end data

end