glitchtip: init at 4.2.5

{

  lib,

  fetchFromGitLab,

  buildNpmPackage,

  jq,

  moreutils,

}:

buildNpmPackage rec {

  pname = "glitchtip-frontend";

  version = "4.2.5";

  src = fetchFromGitLab {

    owner = "glitchtip";

    repo = "glitchtip-frontend";

    tag = "v${version}";

    hash = "sha256-yLpDjHnt8ZwpT+KlmEtXMYgrpnbYlVzJ/MZMELVO/j8=";

  };

  npmDepsHash = "sha256-sR/p/JRVuaemN1euZ/VrJ0j1q7fkS/Zi6R1m6lPvygs=";

  postPatch = ''

    ${lib.getExe jq} '. + {

      "devDependencies": .devDependencies | del(.cypress, ."cypress-localstorage-commands")

    }' package.json | ${lib.getExe' moreutils "sponge"} package.json

  '';

  buildPhase = ''

    runHook preBuild

    npm run build-prod

    runHook postBuild

  '';

  installPhase = ''

    runHook preInstall

    cp -r dist/glitchtip-frontend/browser $out/

    runHook postInstall

  '';

  meta = {

    description = "Frontend for GlitchTip";

    homepage = "https://glitchtip.com";

    changelog = "https://gitlab.com/glitchtip/glitchtip-frontend/-/releases/v${version}";

    license = lib.licenses.mit;

    maintainers = with lib.maintainers; [

      defelo

      felbinger

    ];

  };

}

{

  lib,

  python313,

  fetchFromGitLab,

  callPackage,

  stdenv,

  makeWrapper,

}:

let

  python = python313.override {

    packageOverrides = final: prev: {

      django = final.django_5;

      django-extensions = prev.django-extensions.overridePythonAttrs { doCheck = false; };

    };

  };

  pythonPackages =

    with python.pkgs;

    [

      aiohttp

      anonymizeip

      boto3

      brotli

      celery

      celery-batches

      dj-stripe

      django

      django-allauth

      django-anymail

      django-cors-headers

      django-csp

      django-environ

      django-extensions

      django-import-export

      django-ipware

      django-ninja

      django-organizations

      django-prometheus

      django-redis

      django-sql-utils

      django-storages

      google-cloud-logging

      gunicorn

      orjson

      psycopg

      pydantic

      sentry-sdk

      symbolic

      user-agents

      uvicorn

      uwsgi-chunked

      whitenoise

    ]

    ++ celery.optional-dependencies.redis

    ++ django-allauth.optional-dependencies.mfa

    ++ django-allauth.optional-dependencies.socialaccount

    ++ django-redis.optional-dependencies.hiredis

    ++ django-storages.optional-dependencies.boto3

    ++ django-storages.optional-dependencies.azure

    ++ django-storages.optional-dependencies.google

    ++ psycopg.optional-dependencies.c

    ++ psycopg.optional-dependencies.pool

    ++ pydantic.optional-dependencies.email;

  frontend = callPackage ./frontend.nix { };

in

stdenv.mkDerivation (finalAttrs: {

  pname = "glitchtip";

  version = "4.2.5";

  pyproject = true;

  src = fetchFromGitLab {

    owner = "glitchtip";

    repo = "glitchtip-backend";

    tag = "v${finalAttrs.version}";

    hash = "sha256-OTf2rvx+ONnB7pLB7rinztXL7l2eZfIuI7PosCXaOH8=";

  };

  propagatedBuildInputs = pythonPackages;

  nativeBuildInputs = [

    makeWrapper

    python

  ];

  buildPhase = ''

    runHook preBuild

    export DEBUG=0

    export DEBUG_TOOLBAR=0

    ln -s ${finalAttrs.passthru.frontend} dist

    python3 manage.py collectstatic

    runHook postBuild

  '';

  installPhase = ''

    runHook preInstall

    mkdir -p $out/lib

    cp -r . $out/lib/glitchtip

    chmod +x $out/lib/glitchtip/manage.py

    makeWrapper $out/lib/glitchtip/manage.py $out/bin/glitchtip-manage \

      --prefix PYTHONPATH : "$PYTHONPATH"

    runHook postInstall

  '';

  passthru = {

    inherit frontend;

    updateScript = ./update.sh;

  };

  meta = {

    description = "Open source Sentry API compatible error tracking platform";

    homepage = "https://glitchtip.com";

    changelog = "https://gitlab.com/glitchtip/glitchtip-backend/-/blob/v${finalAttrs.version}/CHANGELOG";

    license = lib.licenses.mit;

    maintainers = with lib.maintainers; [

      defelo

      felbinger

    ];

    mainProgram = "glitchtip-manage";

  };

})

#!/usr/bin/env nix-shell

#!nix-shell -i bash -p nix-update

nix-update glitchtip

nix-update glitchtip.frontend