python3Packages.opaque: init at 1.0.1 (#434602)

{

  lib,

  stdenv,

  fetchFromGitHub,

  libsodium,

  liboprf,

  testers,

  nix-update-script,

}:

stdenv.mkDerivation (finalAttrs: {

  pname = "libopaque";

  version = "1.0.1";

  src = fetchFromGitHub {

    owner = "stef";

    repo = "libopaque";

    tag = "v${finalAttrs.version}";

    hash = "sha256-VVD4489yWAJTWLGrpXYe8or5QjDnAuQ9/tzlNJJu/lo=";

  };

  sourceRoot = "${finalAttrs.src.name}/src";

  strictDeps = true;

  buildInputs = [

    libsodium

    liboprf

  ];

  postInstall = ''

    mkdir -p ${placeholder "out"}/lib/pkgconfig

    cp ../libopaque.pc ${placeholder "out"}/lib/pkgconfig/

  '';

  makeFlags = [ "PREFIX=$(out)" ];

  passthru = {

    tests.pkg-config = testers.testMetaPkgConfig finalAttrs.finalPackage;

    updateScript = nix-update-script { };

  };

  meta = {

    description = "Implementation of the OPAQUE protocol with support for threshold variants";

    homepage = "https://github.com/stef/libopaque/";

    changelog = "https://github.com/stef/libopaque/releases/tag/v${finalAttrs.version}";

    license = lib.licenses.lgpl3Plus;

    teams = [ lib.teams.ngi ];

    platforms = lib.platforms.unix;

    pkgConfigModules = [ "libopaque" ];

  };

})

{

  lib,

  stdenv,

  buildPythonPackage,

  libopaque,

  setuptools,

  pysodium,

  python,

}:

buildPythonPackage rec {

  pname = "opaque";

  pyproject = true;

  inherit (libopaque)

    version

    src

    ;

  sourceRoot = "${src.name}/python";

  postPatch =

    let

      soext = stdenv.hostPlatform.extensions.sharedLibrary;

    in

    ''

      substituteInPlace ./opaque/__init__.py --replace-fail \

        "ctypes.util.find_library('opaque') or ctypes.util.find_library('libopaque')" "'${lib.getLib libopaque}/lib/libopaque${soext}'"

    '';

  build-system = [ setuptools ];

  dependencies = [ pysodium ];

  pythonImportsCheck = [ "opaque" ];

  checkPhase = ''

    runHook preCheck

    ${python.interpreter} test/simple.py

    runHook postCheck

  '';

  meta = {

    inherit (libopaque.meta)

      description

      homepage

      license

      teams

      ;

  };

}

  oocsi = callPackage ../development/python-modules/oocsi { };

  opaque = callPackage ../development/python-modules/opaque { };

  opcua-widgets = callPackage ../development/python-modules/opcua-widgets { };

  open-clip-torch = callPackage ../development/python-modules/open-clip-torch { };