famistudio-bin: Drop

{ lib

, stdenv

, fetchzip

, autoPatchelfHook

, dotnet-runtime

, ffmpeg

, libglvnd

, makeWrapper

, openal

}:

stdenv.mkDerivation (finalAttrs: {

  pname = "famistudio-bin";

  version = "4.1.3";

  src = fetchzip {

    url = "https://github.com/BleuBleu/FamiStudio/releases/download/${finalAttrs.version}/FamiStudio${lib.replaceStrings ["."] [""] finalAttrs.version}-LinuxAMD64.zip";

    stripRoot = false;

    hash = "sha256-eAdv0oObczbs8QLGYbxCrdFk/gN5DOCJ1dp/tg8JWIc=";

  };

  strictDeps = true;

  nativeBuildInputs = [

    autoPatchelfHook

    makeWrapper

  ];

  buildInputs = [

    dotnet-runtime

    ffmpeg

    libglvnd

    openal

  ];

  dontConfigure = true;

  dontBuild = true;

  installPhase = ''

    runHook preInstall

    mkdir -p $out/{bin,lib/famistudio}

    mv * $out/lib/famistudio

    makeWrapper ${lib.getExe dotnet-runtime} $out/bin/FamiStudio \

      --add-flags $out/lib/famistudio/FamiStudio.dll \

      --prefix LD_LIBRARY_PATH : ${lib.makeLibraryPath [ libglvnd ]} \

      --prefix PATH : ${lib.makeBinPath [ ffmpeg ]}

    # Bundled openal lib freezes the application

    rm $out/lib/famistudio/libopenal32.so

    ln -s ${openal}/lib/libopenal.so $out/lib/famistudio/libopenal32.so

    runHook postInstall

  '';

  meta = with lib; {

    homepage = "https://famistudio.org/";

    description = "NES Music Editor (binary distribution)";

    longDescription = ''

      FamiStudio is very simple music editor for the Nintendo Entertainment System

      or Famicom. It is targeted at both chiptune artists and NES homebrewers.

    '';

    license = licenses.mit;

    sourceProvenance = with lib.sourceTypes; [ binaryNativeCode ];

    maintainers = with maintainers; [ OPNA2608 ];

    platforms = [ "x86_64-linux" ];

    mainProgram = "FamiStudio";

  };

})