Merge pull request #302935 from Rucadi/valkey

{ lib, stdenv, fetchFromGitHub, lua, jemalloc, pkg-config

, tcl, which, ps, getconf

, withSystemd ? lib.meta.availableOn stdenv.hostPlatform systemd, systemd

# dependency ordering is broken at the moment when building with openssl

, tlsSupport ? !stdenv.hostPlatform.isStatic, openssl

# Using system jemalloc fixes cross-compilation and various setups.

# However the experimental 'active defragmentation' feature of valkey requires

# their custom patched version of jemalloc.

, useSystemJemalloc ? true

}:

stdenv.mkDerivation (finalAttrs: {

  pname = "valkey";

  version = "7.2.5";

  src = fetchFromGitHub {

    owner = "valkey-io";

    repo = "valkey";

    rev = finalAttrs.version;

    hash = "sha256-nDAQbxlSBXKSJqZgvElsrZeDnHw4A4eA8f9ecXdx0/U=";

  };

  patches = lib.optional useSystemJemalloc ./use_system_jemalloc.patch;

  nativeBuildInputs = [ pkg-config ];

  buildInputs = [ lua ]

    ++ lib.optional useSystemJemalloc jemalloc

    ++ lib.optional withSystemd systemd

    ++ lib.optional tlsSupport openssl;

  preBuild = lib.optionalString stdenv.isDarwin ''

    substituteInPlace src/Makefile --replace-fail "-flto" ""

  '';

  # More cross-compiling fixes.

  makeFlags = [ "PREFIX=${placeholder "out"}" ]

    ++ lib.optionals (stdenv.buildPlatform != stdenv.hostPlatform) [ "AR=${stdenv.cc.targetPrefix}ar" "RANLIB=${stdenv.cc.targetPrefix}ranlib" ]

    ++ lib.optionals withSystemd [ "USE_SYSTEMD=yes" ]

    ++ lib.optionals tlsSupport [ "BUILD_TLS=yes" ];

  enableParallelBuilding = true;

  hardeningEnable = lib.optionals (!stdenv.isDarwin) [ "pie" ];

  env.NIX_CFLAGS_COMPILE = toString (lib.optionals stdenv.cc.isClang [ "-std=c11" ]);

  # darwin currently lacks a pure `pgrep` which is extensively used here

  doCheck = !stdenv.isDarwin;

  nativeCheckInputs = [ which tcl ps ] ++ lib.optionals stdenv.hostPlatform.isStatic [ getconf ];

  checkPhase = ''

    runHook preCheck

    # disable test "Connect multiple replicas at the same time": even

    # upstream find this test too timing-sensitive

    substituteInPlace tests/integration/replication.tcl \

      --replace-fail 'foreach mdl {no yes}' 'foreach mdl {}'

    substituteInPlace tests/support/server.tcl \

      --replace-fail 'exec /usr/bin/env' 'exec env'

    sed -i '/^proc wait_load_handlers_disconnected/{n ; s/wait_for_condition 50 100/wait_for_condition 50 500/; }' \

      tests/support/util.tcl

    ./runtest \

      --no-latency \

      --timeout 2000 \

      --clients $NIX_BUILD_CORES \

      --tags -leaks \

      --skipunit integration/failover # flaky and slow

    runHook postCheck

  '';

  meta = with lib; {

    homepage = "https://valkey.io/";

    description = "A high-performance data structure server that primarily serves key/value workloads";

    license = licenses.bsd3;

    platforms = platforms.all;

    maintainers = with maintainers; [ rucadi ];

    changelog = "https://github.com/valkey-io/valkey/releases/tag/${finalAttrs.version}";

    mainProgram = "valkey-cli";

  };

})

diff --git a/src/Makefile b/src/Makefile

index 3bc9f11c0..a4b23d986 100644

--- a/src/Makefile

+++ b/src/Makefile

@@ -229,8 +229,8 @@ endif

 ifeq ($(MALLOC),jemalloc)

 	DEPENDENCY_TARGETS+= jemalloc

-	FINAL_CFLAGS+= -DUSE_JEMALLOC -I../deps/jemalloc/include

-	FINAL_LIBS := ../deps/jemalloc/lib/libjemalloc.a $(FINAL_LIBS)

+	FINAL_CFLAGS+= -DUSE_JEMALLOC -DJEMALLOC_NO_DEMANGLE -I/usr/include/jemalloc

+	FINAL_LIBS := -ljemalloc $(FINAL_LIBS)

 endif

 ifeq ($(BUILD_TLS),yes)

 No newline at end of file