linuxPackages.tsme-test: init at 6.6.68-unstable-2022-12-07

{

  lib,

  stdenv,

  fetchFromGitHub,

  kernel,

}:

stdenv.mkDerivation {

  pname = "tsme-test";

  version = "${kernel.version}-unstable-2022-12-07";

  src = fetchFromGitHub {

    owner = "AMDESE";

    repo = "mem-encryption-tests";

    rev = "7abb072ffc50ceb0b4145ae84105ce6c91bd1ff4";

    hash = "sha256-v0KAGlo6ci0Ij1NAiMUK0vWDHBiFnpQG4Er6ArIKncQ=";

  };

  nativeBuildInputs = kernel.moduleBuildDependencies;

  makeFlags = kernel.makeFlags ++ [

    "KDIR=${kernel.dev}/lib/modules/${kernel.modDirVersion}/build"

  ];

  installPhase = ''

    runHook preInstall

    install -Dm644 -t $out/lib/modules/${kernel.modDirVersion}/extra tsme-test.ko

    runHook postInstall

  '';

  meta = {

    description = "Kernel driver to test the status of AMD TSME (Transparent Secure Memory Encryption)";

    license = lib.licenses.gpl2Only;

    maintainers = with lib.maintainers; [ lyn ];

    platforms = lib.platforms.linux;

    homepage = "https://github.com/AMDESE/mem-encryption-tests";

  };

}

    msi-ec = callPackage ../os-specific/linux/msi-ec { };

    tsme-test = callPackage ../os-specific/linux/tsme-test { };

  } // lib.optionalAttrs config.allowAliases {

    ati_drivers_x11 = throw "ati drivers are no longer supported by any kernel >=4.1"; # added 2021-05-18;

    hid-nintendo = throw "hid-nintendo was added in mainline kernel version 5.16"; # Added 2023-07-30