Merge pull request #250471 from austinbutler/percollate-init

{ lib, buildNpmPackage, fetchFromGitHub, chromium, makeWrapper }:

buildNpmPackage rec {

  pname = "percollate";

  version = "4.0.2";

  src = fetchFromGitHub {

    owner = "danburzo";

    repo = pname;

    rev = "v${version}";

    hash = "sha256-QLbLg/zdDCZsRKgC4vR0OT//JHaapGmX33l7jIqUc1M=";

  };

  npmDepsHash = "sha256-Hxhgjdiz0zC/UlFXK8vvKZFI963Wi2Wx6iHWegr6f10=";

  dontNpmBuild = true;

  # Dev dependencies include an unnecessary Java dependency (epubchecker)

  # https://github.com/danburzo/percollate/blob/v4.0.2/package.json#L40

  npmInstallFlags = [ "--omit=dev" ];

  nativeBuildInputs = [ makeWrapper ];

  env = {

    PUPPETEER_SKIP_CHROMIUM_DOWNLOAD = true;

  };

  postPatch = ''

    substituteInPlace package.json --replace "git config core.hooksPath .git-hooks" ""

  '';

  postInstall = ''

    wrapProgram $out/bin/percollate \

      --set PUPPETEER_EXECUTABLE_PATH ${chromium}/bin/chromium

  '';

  meta = with lib; {

    description = "A command-line tool to turn web pages into readable PDF, EPUB, HTML, or Markdown docs";

    homepage = "https://github.com/danburzo/percollate";

    license = licenses.mit;

    maintainers = [ maintainers.austinbutler ];

    mainProgram = "percollate";

  };

}

  peco = callPackage ../tools/text/peco { };

  percollate = callPackage ../tools/text/percollate { };

  pg_activity = callPackage ../development/tools/database/pg_activity { };

  pg_checksums = callPackage ../development/tools/database/pg_checksums { };