python312Packages.metaflow: init at 2.13.9

{

  lib,

  buildPythonPackage,

  fetchFromGitHub,

  boto3,

  requests,

  setuptools,

  python,

}:

buildPythonPackage rec {

  pname = "metaflow";

  version = "2.13.9";

  pyproject = true;

  src = fetchFromGitHub {

    owner = "Netflix";

    repo = "metaflow";

    tag = version;

    hash = "sha256-f/cWZl59i1PRqNqLV5LtcZoDKdovdCKoQJNxzXKczgs=";

  };

  build-system = [

    setuptools

  ];

  dependencies = [

    boto3

    requests

  ];

  checkPhase = ''

    runHook preCheck

    export HOME="$TMPDIR"

    export USER="metaflow-test-user"

    pushd test/core

    ${python.interpreter} run_tests.py --num-parallel $NIX_BUILD_CORES \

      --tests FlowOptionsTest,BasicLogTest

    popd

    runHook postCheck

  '';

  pythonImportsCheck = [ "metaflow" ];

  meta = {

    description = "Open Source AI/ML Platform";

    homepage = "https://metaflow.org/";

    changelog = "https://github.com/Netflix/metaflow/releases/tag/${version}";

    license = lib.licenses.asl20;

    maintainers = with lib.maintainers; [ kr7x ];

  };

}

  messagebird = callPackage ../development/python-modules/messagebird { };

  metaflow = callPackage ../development/python-modules/metaflow { };

  metakernel = callPackage ../development/python-modules/metakernel { };

  metar = callPackage ../development/python-modules/metar { };