cisco-packet-tracer_8: drop

{

  lib,

  stdenvNoCC,

  requireFile,

  autoPatchelfHook,

  dpkg,

  makeWrapper,

  alsa-lib,

  dbus,

  expat,

  fontconfig,

  glib,

  libdrm,

  libglvnd,

  libpulseaudio,

  libudev0-shim,

  libxkbcommon,

  libxml2_13,

  libxslt,

  nspr,

  nss,

  wayland,

  libxcb-wm,

  libxcb-render-util,

  libxcb-keysyms,

  libxcb-image,

  libxtst,

  libxscrnsaver,

  libxrender,

  libxrandr,

  libxi,

  libxfixes,

  libxext,

  libxdamage,

  libxcursor,

  libxcomposite,

  libx11,

  libsm,

  libice,

  libxcb,

  buildFHSEnv,

  copyDesktopItems,

  makeDesktopItem,

  libsForQt5,

  version ? "8.2.2",

  packetTracerSource ? null,

}:

let

  hashes = {

    "8.2.0" = "sha256-GxmIXVn2Ew7lVBT7AuIRoXc0YGids4v9Gsfw1FEX7RY=";

    "8.2.1" = "sha256-QoM4rDKkdNTJ6TBDPCAs+l17JLnspQFlly9B60hOB7o=";

    "8.2.2" = "sha256-bNK4iR35LSyti2/cR0gPwIneCFxPP+leuA1UUKKn9y0=";

  };

  names = {

    "8.2.0" = "CiscoPacketTracer_820_Ubuntu_64bit.deb";

    "8.2.1" = "CiscoPacketTracer_821_Ubuntu_64bit.deb";

    "8.2.2" = "CiscoPacketTracer822_amd64_signed.deb";

  };

  unwrapped = stdenvNoCC.mkDerivation {

    name = "cisco-packet-tracer-unwrapped";

    inherit version;

    src =

      if (packetTracerSource != null) then

        packetTracerSource

      else

        requireFile {

          name = names.${version};

          hash = hashes.${version};

          url = "https://www.netacad.com";

        };

    nativeBuildInputs = [

      autoPatchelfHook

      dpkg

      makeWrapper

    ];

    buildInputs = [

      alsa-lib

      dbus

      expat

      fontconfig

      glib

      libdrm

      libglvnd

      libpulseaudio

      libudev0-shim

      libxkbcommon

      libxml2_13

      libxslt

      nspr

      nss

      wayland

      libice

      libsm

      libx11

      libxscrnsaver

      libxcomposite

      libxcursor

      libxdamage

      libxext

      libxfixes

      libxi

      libxrandr

      libxrender

      libxtst

      libxcb

      libxcb-image

      libxcb-keysyms

      libxcb-render-util

      libxcb-wm

    ];

    unpackPhase = ''

      runHook preUnpack

      dpkg-deb -x $src $out

      chmod 755 "$out"

      runHook postUnpack

    '';

    installPhase = ''

      runHook preInstall

      makeWrapper "$out/opt/pt/bin/PacketTracer" "$out/bin/packettracer8" \

        --set QT_QPA_PLATFORM xcb \

        --prefix LD_LIBRARY_PATH : "$out/opt/pt/bin"

      runHook postInstall

    '';

  };

  fhs-env = buildFHSEnv {

    pname = "cisco-packet-tracer-fhs-env";

    inherit version;

    runScript = lib.getExe' unwrapped "packettracer8";

    targetPkgs = _: [ libudev0-shim ];

  };

in

stdenvNoCC.mkDerivation {

  pname = "cisco-packet-tracer";

  inherit version;

  dontUnpack = true;

  nativeBuildInputs = [

    copyDesktopItems

  ];

  installPhase = ''

    runHook preInstall

    mkdir -p $out/bin

    ln -s ${fhs-env}/bin/${fhs-env.pname} $out/bin/packettracer8

    mkdir -p $out/share/icons/hicolor/48x48/apps

    ln -s ${unwrapped}/opt/pt/art/app.png $out/share/icons/hicolor/48x48/apps/cisco-packet-tracer-8.png

    ln -s ${unwrapped}/usr/share/icons/gnome/48x48/mimetypes $out/share/icons/hicolor/48x48/mimetypes

    ln -s ${unwrapped}/usr/share/mime $out/share/mime

    runHook postInstall

  '';

  desktopItems = [

    (makeDesktopItem {

      name = "cisco-pt8.desktop";

      desktopName = "Cisco Packet Tracer 8";

      icon = "cisco-packet-tracer-8";

      exec = "packettracer8 %f";

      mimeTypes = [

        "application/x-pkt"

        "application/x-pka"

        "application/x-pkz"

        "application/x-pksz"

        "application/x-pks"

      ];

    })

  ];

  meta = {

    description = "Network simulation tool from Cisco";

    homepage = "https://www.netacad.com/courses/packet-tracer";

    license = lib.licenses.unfree;

    mainProgram = "packettracer8";

    maintainers = with lib.maintainers; [

      gepbird

    ];

    platforms = [ "x86_64-linux" ];

    sourceProvenance = with lib.sourceTypes; [ binaryNativeCode ];

    knownVulnerabilities = [

      ''

        Cisco Packet Tracer 8 ships with qt5 qtwebengine.

        ${lib.head libsForQt5.qtwebengine.meta.knownVulnerabilities}

      ''

    ];

  };

}

  chrome-gnome-shell = throw "'chrome-gnome-shell' has been renamed to/replaced by 'gnome-browser-connector'"; # Converted to throw 2025-10-27

  ci-edit = throw "'ci-edit' has been removed due to lack of maintenance upstream"; # Added 2025-08-26

  cinnamon-common = cinnamon; # Added 2025-08-06

  cisco-packet-tracer_8 = throw "'cisco-packet-tracer_8' has been removed as it vendored qt5 webengine. Consider updating to 'cisco-packet-tracer_9' instead."; # Added 2026-04-26

  ciscoPacketTracer7 = throw "'ciscoPacketTracer7' has been removed in favor of 'cisco-packet-tracer_8' and 'cisco-packet-tracer_9'";

  ciscoPacketTracer8 = cisco-packet-tracer_8; # Added 2026-02-08

  ciscoPacketTracer9 = cisco-packet-tracer_9; # Added 2026-02-08