Unverified Commit bc2794b3 authored by Michael Daniels's avatar Michael Daniels Committed by GitHub
Browse files

awakened-poe-trade: init at 3.27.106 (#485503)

parents fc874de7 4208aeb1

maintainers/maintainer-list.nix

+6 −0
Original line number Diff line number Diff line
@@ -18055,6 +18055,12 @@ 
    githubId = 3073833;

    name = "Massimo Redaelli";

  };

  mreichardt95 = {

    email = "mreichardt95@gmail.com";

    github = "mreichardt95";

    githubId = 18323490;

    name = "Milian Reichardt";

  };

  mrene = {

    email = "mathieu.rene@gmail.com";

    github = "mrene";

pkgs/by-name/aw/awakened-poe-trade/package.nix

0 → 100644
+74 −0
Original line number Diff line number Diff line 
{

  lib,

  fetchurl,

  stdenv,

  appimageTools,

  makeWrapper,

  electron,

  libxtst,

  libxt,



  nix-update-script,

}:



stdenv.mkDerivation (finalAttrs: {

  pname = "awakened-poe-trade";

  version = "3.27.106";



  src = fetchurl {

    url = "https://github.com/SnosMe/awakened-poe-trade/releases/download/v${finalAttrs.version}/Awakened-PoE-Trade-${finalAttrs.version}.AppImage";

    hash = "sha256-8L5Szn0KYfUMaTe+yyhJV1YZspmJCSlXSHXLPoiRhjE=";

  };



  passthru = {

    appImageContents = appimageTools.extractType2 {

      inherit (finalAttrs) pname src version;

    };



    updateScript = nix-update-script { };

  };



  dontUnpack = true;

  dontConfigure = true;

  dontBuild = true;



  nativeBuildInputs = [ makeWrapper ];



  installPhase = ''

    runHook preInstall

    mkdir -p $out/bin $out/share/awakened-poe-trade $out/share/applications



    cp -a ${finalAttrs.passthru.appImageContents}/{locales,resources} $out/share/awakened-poe-trade

    cp -a ${finalAttrs.passthru.appImageContents}/awakened-poe-trade.desktop $out/share/applications/

    cp -a ${finalAttrs.passthru.appImageContents}/usr/share/icons $out/share



    substituteInPlace $out/share/applications/awakened-poe-trade.desktop \

      --replace-fail 'Exec=AppRun' 'Exec=awakened-poe-trade'



    runHook postInstall

  '';



  postFixup = ''

    makeWrapper ${lib.getExe electron} $out/bin/awakened-poe-trade \

      --add-flags $out/share/awakened-poe-trade/resources/app.asar \

      --prefix LD_LIBRARY_PATH : "${

        lib.makeLibraryPath [

          libxtst

          libxt

        ]

      }"

  '';



  meta = {

    description = "Path of Exile trading app for price checking";

    homepage = "https://github.com/SnosMe/awakened-poe-trade";

    changelog = "https://github.com/SnosMe/awakened-poe-trade/releases/tag/v${finalAttrs.version}";

    sourceProvenance = [ lib.sourceTypes.binaryNativeCode ];

    license = lib.licenses.mit;

    maintainers = with lib.maintainers; [

      mreichardt95

    ];

    platforms = with lib.platforms; linux;

    mainProgram = "awakened-poe-trade";

  };

})