findent: init at 4.3.6, ford: init at 7.0.13 (#503674)

{

  stdenv,

  lib,

  fetchurl,

}:

stdenv.mkDerivation (finalAttrs: {

  pname = "findent";

  version = "4.3.6";

  src = fetchurl {

    url = "mirror://sourceforge/findent/findent-${finalAttrs.version}.tar.gz";

    hash = "sha256-ctg02P8P3R27lCpv3tILSZ5ikn2Va25jHOWIuRfIONQ=";

  };

  enableParallelBuilding = true;

  doCheck = true;

  checkTargets = [ "installcheck" ];

  meta = {

    description = "Fortran source code formatter";

    homepage = "https://sourceforge.net/findent/";

    license = lib.licenses.bsd3;

    mainProgram = "findent";

    maintainers = with lib.maintainers; [ sheepforce ];

    platforms = [ "x86_64-linux" ];

  };

})

{

  lib,

  python3Packages,

  fetchFromGitHub,

  gfortran,

}:

python3Packages.buildPythonApplication (finalAttrs: {

  pname = "ford";

  version = "7.0.13";

  src = fetchFromGitHub {

    owner = "Fortran-FOSS-Programmers";

    repo = "ford";

    tag = "v${finalAttrs.version}";

    hash = "sha256-+pz4YvMmr7QIqrORJg0F2W7m20FTrItHCC+AmcDp284=";

  };

  pyproject = true;

  nativeBuildInputs = [ python3Packages.pythonRelaxDepsHook ];

  pythonRelaxDeps = [

    "markdown"

    "markdown-include"

    "toposort"

    "graphviz"

  ];

  build-system = with python3Packages; [

    setuptools

    setuptools-scm

  ];

  dependencies = with python3Packages; [

    markdown

    markdown-include

    toposort

    jinja2

    pygments

    beautifulsoup4

    graphviz

    tqdm

    tomli

    rich

    pcpp

    python-markdown-math

  ];

  nativeCheckInputs = with python3Packages; [

    pytestCheckHook

    tomli-w

    pcpp

    gfortran

  ];

  meta = {

    description = "Fortran documentation system";

    mainProgram = "ford";

    homepage = "https://github.com/Fortran-FOSS-Programmers/ford";

    license = [ lib.licenses.gpl3Only ];

    maintainers = [ lib.maintainers.sheepforce ];

  };

})