python3Packages.uv-build: init at 0.6.6 (#388519)

{

  buildPythonPackage,

  uv,

  uv-build,

  anyio,

  pytestCheckHook,

}:

buildPythonPackage {

  pname = "built-by-uv";

  version = "0.1.0";

  pyproject = true;

  src = "${uv.src}/scripts/packages/built-by-uv";

  build-system = [ uv-build ];

  dependencies = [ anyio ];

  pythonImportsCheck = [ "built_by_uv" ];

  nativeCheckInputs = [ pytestCheckHook ];

}

{

  lib,

  pkgs,

  buildPythonPackage,

  rustPlatform,

  callPackage,

}:

buildPythonPackage {

  pname = "uv-build";

  pyproject = true;

  inherit (pkgs.uv)

    version

    src

    cargoDeps

    cargoBuildFlags

    ;

  nativeBuildInputs = [

    rustPlatform.cargoSetupHook

    rustPlatform.maturinBuildHook

  ];

  buildAndTestSubdir = "crates/uv-build";

  # $src/.github/workflows/build-binaries.yml#L139

  maturinBuildFlags = [ "--profile=minimal-size" ];

  pythonImportsCheck = [ "uv_build" ];

  # The package has no tests

  doCheck = false;

  # Run the tests of a package built by `uv_build`.

  passthru.tests.built-by-uv = callPackage ./built-by-uv.nix { inherit (pkgs) uv; };

  meta = {

    description = "A minimal build backend for uv";

    inherit (pkgs.uv.meta) homepage changelog license;

    maintainers = with lib.maintainers; [ bengsparks ];

  };

}

  uv = callPackage ../development/python-modules/uv { };

  uv-build = callPackage ../development/python-modules/uv-build { };

  uv-dynamic-versioning = callPackage ../development/python-modules/uv-dynamic-versioning { };

  uvcclient = callPackage ../development/python-modules/uvcclient { };