Merge pull request #249843 from lilyinstarlight/pkg/openutau

{ lib

, stdenv

, buildDotnetModule

, fetchFromGitHub

, dotnetCorePackages

, dbus

, fontconfig

, libICE

, libSM

, libX11

, portaudio

}:

buildDotnetModule rec {

  pname = "OpenUtau";

  version = "0.1.158";

  src = fetchFromGitHub {

    owner = "stakira";

    repo = "OpenUtau";

    rev = "build/${version}";

    hash = "sha256-/+hlL2sj/juzWrDcb5dELp8Zdg688XK8OnjKz20rx/M=";

  };

  dotnet-sdk = dotnetCorePackages.sdk_7_0;

  dotnet-runtime = dotnetCorePackages.runtime_7_0;

  projectFile = "OpenUtau.sln";

  nugetDeps = ./deps.nix;

  executables = [ "OpenUtau" ];

  runtimeDeps = [

    dbus

    fontconfig

    libICE

    libSM

    libX11

    portaudio

  ];

  dotnetInstallFlags = [ "-p:PublishReadyToRun=false" ];

  # socket cannot bind to localhost on darwin for tests

  doCheck = !stdenv.isDarwin;

  # needed until upstream bumps to dotnet 7

  postPatch = ''

    substituteInPlace OpenUtau/OpenUtau.csproj OpenUtau.Test/OpenUtau.Test.csproj --replace \

      "<TargetFramework>net6.0</TargetFramework>" \

      "<TargetFramework>net7.0</TargetFramework>"

  '';

  # need to make sure proprietary worldline resampler is copied

  postInstall = let

    runtime = if (stdenv.isLinux && stdenv.isx86_64) then "linux-x64"

         else if (stdenv.isLinux && stdenv.isAarch64) then "linux-arm64"

         else if stdenv.isDarwin then "osx"

         else null;

  in lib.optionalString (runtime != null) ''

    cp runtimes/${runtime}/native/libworldline${stdenv.hostPlatform.extensions.sharedLibrary} $out/lib/OpenUtau/

  '';

  passthru.updateScript = ./update.sh;

  meta = with lib; {

    description = "Open source singing synthesis platform and UTAU successor";

    homepage = "http://www.openutau.com/";

    sourceProvenance = with sourceTypes; [

      fromSource

      # deps

      binaryBytecode

      # some deps and worldline resampler

      binaryNativeCode

    ];

    license = with licenses; [

      # dotnet code

      mit

      # worldline resampler

      unfree

    ];

    maintainers = with maintainers; [ lilyinstarlight ];

    platforms = [ "x86_64-linux" "aarch64-linux" "x86_64-darwin" "aarch64-darwin" ];

  };

}

#!/usr/bin/env nix-shell

#!nix-shell -i bash -p bash curl nix jq common-updater-scripts

set -euo pipefail

nixpkgs="$(git rev-parse --show-toplevel || (printf 'Could not find root of nixpkgs repo\nAre we running from within the nixpkgs git repo?\n' >&2; exit 1))"

stripwhitespace() {

    sed -e 's/^[[:space:]]*//' -e 's/[[:space:]]*$//'

}

nixeval() {

    nix --extra-experimental-features nix-command eval --json --impure -f "$nixpkgs" "$1" | jq -r .

}

nixbuildscript() {

    nix --extra-experimental-features nix-command build --impure -f "$nixpkgs" "$1" --no-link --print-out-paths

}

findpath() {

    path="$(nix --extra-experimental-features nix-command eval --json --impure -f "$nixpkgs" "$1.meta.position" | jq -r . | cut -d: -f1)"

    outpath="$(nix --extra-experimental-features nix-command eval --json --impure --expr "builtins.fetchGit \"$nixpkgs\"")"

    if [ -n "$outpath" ]; then

        path="${path/$(echo "$outpath" | jq -r .)/$nixpkgs}"

    fi

    echo "$path"

}

attr="${UPDATE_NIX_ATTR_PATH:-openutau}"

version="$(curl -sSL "https://api.github.com/repos/stakira/OpenUtau/releases/latest" | jq -r .tag_name | sed -e 's|^build/||')"

pkgpath="$(findpath "$attr")"

updated="$(cd "$nixpkgs" && update-source-version "$attr" "$version" --file="$pkgpath" --print-changes | jq -r length)"

if [ "$updated" -eq 0 ]; then

    echo 'update.sh: Package version not updated, nothing to do.'

    exit 0

fi

(cd "$(dirname "$pkgpath")" && "$(nixbuildscript "$attr.fetch-deps")" "$(dirname "$pkgpath")/deps.nix")

  muzika = callPackage ../applications/audio/muzika { };

  openutau = callPackage ../applications/audio/openutau { };

  pattypan = callPackage ../applications/misc/pattypan {

    jdk = jdk.override { enableJavaFX = true; };

  };