constrict: init at 25.12.1 (#478601)

{

  lib,

  python3Packages,

  fetchFromGitHub,

  meson,

  ninja,

  pkg-config,

  blueprint-compiler,

  gobject-introspection,

  wrapGAppsHook4,

  desktop-file-utils,

  libadwaita,

  libglycin,

  libva-utils,

  ffmpeg,

  gst-thumbnailers,

  glycin-loaders,

}:

python3Packages.buildPythonApplication (finalAttrs: {

  pname = "constrict";

  version = "25.12.1";

  pyproject = false; # Built with meson

  src = fetchFromGitHub {

    owner = "Wartybix";

    repo = "Constrict";

    tag = finalAttrs.version;

    hash = "sha256-ZSiBlejNFakz+/3qj3n+ekB5l9JOk3MiQ8PRZOdxtLQ=";

  };

  nativeBuildInputs = [

    meson

    ninja

    pkg-config

    blueprint-compiler

    gobject-introspection

    wrapGAppsHook4

    desktop-file-utils

  ];

  buildInputs = [

    libadwaita

    libglycin

  ];

  dependencies = [

    python3Packages.pygobject3

  ];

  # Search for use of subprocess

  runtimeDeps = [

    libva-utils

    ffmpeg

    gst-thumbnailers

  ];

  dontWrapGApps = true;

  preFixup = ''

    makeWrapperArgs+=(

      ''${gappsWrapperArgs[@]}

      --prefix XDG_DATA_DIRS : "${glycin-loaders}/share"

      --prefix PATH : ${lib.makeBinPath finalAttrs.runtimeDeps}

    )

  '';

  meta = {

    description = "Compresses your videos to your chosen file size";

    homepage = "https://github.com/Wartybix/Constrict";

    changelog = "https://github.com/Wartybix/Constrict/releases/tag/${finalAttrs.src.tag}";

    license = lib.licenses.gpl3Plus;

    mainProgram = "constrict";

    teams = [ lib.teams.gnome-circle ];

    platforms = lib.platforms.linux;

  };

})

{

  lib,

  stdenv,

  fetchFromGitLab,

  rustPlatform,

  meson,

  ninja,

  pkg-config,

  cargo,

  rustc,

  wrapGAppsNoGuiHook,

  gst_all_1,

  fontconfig,

  libglycin,

  glycin-loaders,

}:

stdenv.mkDerivation (finalAttrs: {

  pname = "gst-thumbnailers";

  version = "1.0.alpha.1";

  src = fetchFromGitLab {

    domain = "gitlab.gnome.org";

    owner = "GNOME";

    repo = "gst-thumbnailers";

    tag = finalAttrs.version;

    hash = "sha256-LOdD8ECSK+QuXkE8jjIg5IfZSQ5FcIi3hmZ2vAaaBKI=";

  };

  cargoDeps = rustPlatform.fetchCargoVendor {

    inherit (finalAttrs) pname version src;

    hash = "sha256-PIqEEijKe+wsX6idqoIB591h1Yj4mixwXDKDN4caO9I=";

  };

  nativeBuildInputs = [

    meson

    ninja

    pkg-config

    rustPlatform.cargoSetupHook

    cargo

    rustc

    wrapGAppsNoGuiHook

  ];

  buildInputs = [

    gst_all_1.gst-plugins-base

    gst_all_1.gst-plugins-good

    gst_all_1.gst-plugins-bad

    gst_all_1.gst-plugins-ugly

    fontconfig

    libglycin

  ];

  preFixup = ''

    gappsWrapperArgs+=(

      --prefix XDG_DATA_DIRS : "${glycin-loaders}/share"

    )

  '';

  meta = {

    description = "Generate thumbnailer for video and audio files";

    homepage = "https://gitlab.gnome.org/GNOME/gst-thumbnailers";

    license = lib.licenses.gpl3Plus;

    maintainers = [ lib.maintainers.aleksana ];

    platforms = lib.platforms.linux;

  };

})