python313Packages.hydra-joblib-plugin: init at 1.3.2 (#423298)

{

  lib,

  buildPythonPackage,

  fetchFromGitHub,

  # build-system

  setuptools,

  # dependencies

  hydra-core,

  joblib,

  # test

  pytestCheckHook,

}:

buildPythonPackage rec {

  pname = "hydra-joblib-launcher";

  pyproject = true;

  inherit (hydra-core) version src;

  sourceRoot = "${src.name}/plugins/hydra_joblib_launcher";

  # get rid of deprecated "read_version" dependency, no longer in Nixpkgs:

  postPatch = ''

    substituteInPlace pyproject.toml --replace-fail ', "read-version"' ""

    substituteInPlace setup.py  \

      --replace-fail 'from read_version import read_version' ""  \

      --replace-fail 'version=read_version("hydra_plugins/hydra_joblib_launcher", "__init__.py"),' 'version="${version}",'

  '';

  build-system = [

    setuptools

  ];

  dependencies = [

    hydra-core

    joblib

  ];

  nativeCheckInputs = [

    pytestCheckHook

  ];

  # tries to write to source directory otherwise:

  pytestFlagsArray = [ "-p no:cacheprovider" ];

  meta = {

    inherit (hydra-core.meta) changelog license;

    description = "Hydra launcher supporting parallel execution based on Joblib.Parallel";

    homepage = "https://hydra.cc/docs/plugins/joblib_launcher";

    maintainers = with lib.maintainers; [ bcdarwin ];

  };

}

  hydra-core = callPackage ../development/python-modules/hydra-core { };

  hydra-joblib-launcher = callPackage ../development/python-modules/hydra-joblib-launcher { };

  hydrawiser = callPackage ../development/python-modules/hydrawiser { };

  hydrogram = callPackage ../development/python-modules/hydrogram { };