hydrogen-web: init at 0.4.0

{ lib

, stdenv

, fetchFromGitHub

, fetchYarnDeps

, yarn

, fixup_yarn_lock

, nodejs

}:

stdenv.mkDerivation (finalAttrs: {

  pname = "hydrogen-web";

  version = "0.4.0";

  src = fetchFromGitHub {

    owner = "vector-im";

    repo = finalAttrs.pname;

    rev = "v${finalAttrs.version}";

    hash = "sha256-u8Yex3r7EZH+JztQHJbfncYeyyl6hgb1ZNFIg//wcb0=";

  };

  offlineCache = fetchYarnDeps {

    yarnLock = finalAttrs.src + "/yarn.lock";

    hash = "sha256-N9lUAhfYLlEAIaWSNS3Ecq+aBTz+f7Z22Sclwj9rp6w=";

  };

  nativeBuildInputs = [ yarn fixup_yarn_lock nodejs ];

  configurePhase = ''

    runHook preConfigure

    export HOME=$PWD/tmp

    mkdir -p $HOME

    fixup_yarn_lock yarn.lock

    yarn config --offline set yarn-offline-mirror $offlineCache

    yarn install --offline --frozen-lockfile --ignore-platform --ignore-scripts --no-progress --non-interactive

    patchShebangs node_modules

    runHook postConfigure

  '';

  buildPhase = ''

    runHook preBuild

    yarn build --offline

    runHook postBuild

  '';

  installPhase = ''

    runHook preInstall

    cp -R target $out

    runHook postInstall

  '';

  meta = {

    description = "Lightweight matrix client with legacy and mobile browser support";

    homepage = "https://github.com/vector-im/hydrogen-web";

    maintainers = lib.teams.matrix.members;

    license = lib.licenses.asl20;

    platforms = lib.platforms.all;

  };

})

{ stdenv

, jq

, hydrogen-web-unwrapped

, conf ? { }

}:

if (conf == { }) then hydrogen-web-unwrapped else

stdenv.mkDerivation {

  pname = "${hydrogen-web-unwrapped.pname}-wrapped";

  inherit (hydrogen-web-unwrapped) version meta;

  dontUnpack = true;

  nativeBuildInputs = [ jq ];

  installPhase = ''

    runHook preInstall

    mkdir -p $out

    ln -s ${hydrogen-web-unwrapped}/* $out

    rm $out/config.json

    jq -s '.[0] * $conf' "${hydrogen-web-unwrapped}/config.json" --argjson "conf" '${builtins.toJSON conf}' > "$out/config.json"

    runHook postInstall

  '';

}

  hipchat = callPackage ../applications/networking/instant-messengers/hipchat { };

  hydrogen-web-unwrapped = callPackage ../applications/networking/instant-messengers/hydrogen-web/unwrapped.nix { };

  hydrogen-web = callPackage ../applications/networking/instant-messengers/hydrogen-web/wrapper.nix {

    conf = config.hydrogen-web.conf or { };

  };

  hivelytracker = callPackage ../applications/audio/hivelytracker { };

  hledger = haskell.lib.compose.justStaticExecutables haskellPackages.hledger;