vfox: init at 0.6.10

{

  lib,

  buildGoModule,

  fetchFromGitHub,

  writableTmpDirAsHomeHook,

  nix-update-script,

}:

buildGoModule (finalAttrs: {

  pname = "vfox";

  version = "0.6.10";

  src = fetchFromGitHub {

    owner = "version-fox";

    repo = "vfox";

    tag = "v${finalAttrs.version}";

    hash = "sha256-bH7rHhjmfXCOAv+K0HDyPAi+ZBfLllsGyhLSo8rpcl4=";

  };

  vendorHash = "sha256-TmWhzjjv+DkFHV4kEKpVYgQpI0Vl4aYvKR9QVpawrYA=";

  __darwinAllowLocalNetworking = true;

  nativeCheckInputs = [ writableTmpDirAsHomeHook ];

  checkFlags =

    let

      skippedTests = [

        # need network

        "TestGetRequest"

        "TestHeadRequest"

        "TestDownloadFile"

      ];

    in

    [ "-skip=^${builtins.concatStringsSep "$|^" skippedTests}$" ];

  preCheck = ''

    export CI=1

  '';

  passthru.updateScript = nix-update-script { };

  meta = {

    description = "Extendable version manager";

    homepage = "https://github.com/version-fox/vfox";

    changelog = "https://github.com/version-fox/vfox/releases/tag/v${finalAttrs.version}";

    mainProgram = "vfox";

    license = lib.licenses.asl20;

    maintainers = with lib.maintainers; [ emaryn ];

  };

})