Unverified Commit 80b5bad0 authored by jopejoe1's avatar jopejoe1 Committed by GitHub
Browse files

nodePackages: migrate/drop more packages (#460403)

parents 0f978ad6 a399fb09

pkgs/by-name/cd/cdk8s-cli/package.nix

0 → 100644
+55 −0
Original line number Diff line number Diff line 
{

  lib,

  stdenv,

  fetchFromGitHub,

  fetchYarnDeps,

  yarnConfigHook,

  yarnBuildHook,

  yarnInstallHook,

  nodejs,

  nix-update-script,

}:



stdenv.mkDerivation (finalAttrs: {

  pname = "cdk8s-cli";

  version = "2.203.1";



  src = fetchFromGitHub {

    owner = "cdk8s-team";

    repo = "cdk8s-cli";

    rev = "v${finalAttrs.version}";

    hash = "sha256-vp4AdAreL7qFp91l0OTwHJuqatCrBRRlXZ4cydQy2H0=";

  };



  yarnOfflineCache = fetchYarnDeps {

    inherit (finalAttrs) src;

    hash = "sha256-0lsA4FabwKF5JoCU2JlcEcgldGeICUZtl1kAcI7sqSQ=";

  };



  nativeBuildInputs = [

    yarnConfigHook

    yarnBuildHook

    yarnInstallHook

    nodejs

  ];



  # Skip tests, they need network access

  env.SKIP_TESTS = 1;



  # Set the version properly, setting it earlier makes the build fail

  # because `projen` requires a version of 0.0.0 in the package.json

  postInstall = ''

    substituteInPlace $out/lib/node_modules/cdk8s-cli/package.json \

      --replace-fail '0.0.0' '${finalAttrs.version}'

  '';



  passthru.updateScript = nix-update-script { };



  meta = {

    description = "Command-line-interface for CDK for Kubernetes";

    homepage = "https://github.com/cdk8s-team/cdk8s-cli";

    license = lib.licenses.asl20;

    maintainers = with lib.maintainers; [ pyrox0 ];

    mainProgram = "cdk8s";

  };

})

pkgs/by-name/pe/peerflix-server/package.nix

0 → 100644
+35 −0
Original line number Diff line number Diff line 
{

  lib,

  buildNpmPackage,

  fetchFromGitHub,

  nix-update-script,

}:



buildNpmPackage (finalAttrs: {

  pname = "peerflix-server";

  version = "0.6.0";



  src = fetchFromGitHub {

    owner = "asapach";

    repo = "peerflix-server";

    tag = "v${finalAttrs.version}";

    hash = "sha256-on1k6ONCI267h+hXlF0kveLFO5KSoEI1EqFCbphYMhI=";

  };



  npmDepsHash = "sha256-1RCuVZcasFmuPXyGlHxUE1AB5rCeVk2ctst2z1X5Ubw=";



  npmFlags = [ "--ignore-scripts" ];



  dontNpmBuild = true;

  dontNpmPrune = true;



  passthru.updateScript = nix-update-script { };



  meta = {

    description = "Streaming torrent client for Node.js with web ui";

    homepage = "https://github.com/asapach/peerflix-server";

    license = lib.licenses.mit;

    maintainers = with lib.maintainers; [ pyrox0 ];

    mainProgram = "peerflix-server";

  };

})

pkgs/by-name/sv/svelte-check/package.nix

0 → 100644
+80 −0
Original line number Diff line number Diff line 
{

  lib,

  stdenv,

  fetchFromGitHub,

  pnpm,

  nodejs,

  makeBinaryWrapper,

  nix-update-script,

}:

stdenv.mkDerivation (finalAttrs: {

  pname = "svelte-check";

  version = "4.3.1";



  src = fetchFromGitHub {

    owner = "sveltejs";

    repo = "language-tools";

    tag = "svelte-check-${finalAttrs.version}";

    hash = "sha256-+KDl7tTyXo6QMQpMGA4hSChDaPrfqfVKJXGunTlo9Rg=";

  };



  pnpmWorkspaces = [ "svelte-check..." ];



  pnpmDeps = pnpm.fetchDeps {

    inherit (finalAttrs)

      pname

      version

      src

      pnpmWorkspaces

      ;

    fetcherVersion = 2;

    hash = "sha256-3bsY31sp5hjTYhRiZniAMVb3kZ1EqOlbyOvljU8jHlY=";

  };



  nativeBuildInputs = [

    nodejs

    pnpm.configHook

    makeBinaryWrapper

  ];



  buildPhase = ''

    runHook preBuild



    pnpm run --filter=svelte-check... build



    runHook postBuild

  '';



  installPhase = ''

    runHook preInstall



    pnpm install --filter=svelte-check... --frozen-lockfile --offline --force --ignore-scripts

    mkdir -p $out/lib/node_modules/svelte-check/

    mkdir -p $out/bin



    mv {packages,node_modules} $out/lib/node_modules/svelte-check/



    makeWrapper ${lib.getExe nodejs} $out/bin/svelte-check \

      --add-flags "$out/lib/node_modules/svelte-check/packages/svelte-check/bin/svelte-check" \

      --set NODE_PATH "$out/lib/node_modules/svelte-check/packages/svelte-check/node_modules/"



    runHook postInstall

  '';



  passthru.updateScript = nix-update-script {

    extraArgs = [

      "--use-github-releases"

      "--version-regex"

      "svelte-check-(.*)"

    ];

  };



  meta = {

    description = "Svelte code checker";

    downloadPage = "https://www.npmjs.com/package/svelte-check";

    homepage = "https://github.com/sveltejs/language-tools";

    license = lib.licenses.mit;

    mainProgram = "svelte-check";

    maintainers = with lib.maintainers; [ pyrox0 ];

  };

})

pkgs/by-name/ti/tiddlywiki/package.nix

0 → 100644
+43 −0
Original line number Diff line number Diff line 
{

  lib,

  stdenv,

  fetchFromGitHub,

  makeBinaryWrapper,

  nodejs,

  nix-update-script,

}:



stdenv.mkDerivation (finalAttrs: {

  pname = "tiddlywiki";

  version = "5.3.8";



  src = fetchFromGitHub {

    owner = "tiddlywiki";

    repo = "tiddlywiki5";

    tag = "v${finalAttrs.version}";

    hash = "sha256-nBBjD9JB4tliRJ5N1aK3pc9PzCHG1fByj7vWtKnNEzI=";

  };



  nativeBuildInputs = [

    makeBinaryWrapper

    nodejs

  ];



  installPhase = ''

    mkdir -p $out/lib/node_modules/tiddlywiki/

    mv * $out/lib/node_modules/tiddlywiki/



    makeWrapper ${lib.getExe nodejs} $out/bin/tiddlywiki \

      --add-flags "$out/lib/node_modules/tiddlywiki/tiddlywiki.js"

  '';



  passthru.updateScript = nix-update-script { };



  meta = {

    description = "Self-contained JavaScript wiki for the browser, Node.js, AWS Lambda etc";

    homepage = "https://tiddlywiki.com";

    license = lib.licenses.bsd3;

    maintainers = with lib.maintainers; [ pyrox0 ];

    mainProgram = "tiddlywiki";

  };

})

pkgs/development/node-packages/aliases.nix

+8 −0
Original line number Diff line number Diff line
@@ -82,6 +82,7 @@ mapAliases { 
  inherit (pkgs) carbon-now-cli; # added 2023-08-17

  inherit (pkgs) carto; # added 2023-08-17

  castnow = pkgs.castnow; # added 2023-07-30

  inherit (pkgs) cdk8s-cli; # Added 2025-11-10

  inherit (pkgs) cdktf-cli; # added 2025-10-02

  inherit (pkgs) clean-css-cli; # added 2023-08-18

  inherit (pkgs) coc-clangd; # added 2024-06-29
@@ -199,7 +200,9 @@ mapAliases { 
  inherit (pkgs) js-beautify; # Added 2025-11-06

  inherit (pkgs) jshint; # Added 2025-11-06

  inherit (pkgs) json-diff; # Added 2025-11-07

  jsonlint = throw "'jsonlint' has been removed because it is unmaintained upstream"; # Added 2025-11-10

  inherit (pkgs) jsonplaceholder; # Added 2025-11-04

  json-refs = throw "'json-refs' has been removed because it is unmaintained and has several known vulnerable dependencies"; # Added 2025-11-10

  inherit (pkgs) json-server; # Added 2025-11-06

  joplin = pkgs.joplin-cli; # Added 2025-11-02

  inherit (pkgs) kaput-cli; # added 2024-12-03
@@ -210,6 +213,7 @@ mapAliases { 
  inherit (pkgs) lerna; # added 2025-02-12

  less = pkgs.lessc; # added 2024-06-15

  less-plugin-clean-css = pkgs.lessc.plugins.clean-css; # added 2024-06-15

  livedown = throw "'livedown' has been removed because it was unmaintained"; # Added 2025-11-10

  inherit (pkgs) localtunnel; # Added 2025-11-08

  lodash = throw "lodash was removed because it provides no executable"; # added 2025-03-18

  lua-fmt = throw "'lua-fmt' has been removed because it has critical bugs that break formatting"; # Added 2025-11-07
@@ -225,6 +229,7 @@ mapAliases { 
  inherit (pkgs) mermaid-cli; # added 2023-10-01

  meshcommander = throw "meshcommander was removed because it was abandoned upstream"; # added 2024-12-02

  inherit (pkgs) mocha; # Added 2025-11-04

  multi-file-swagger = throw "'multi-file-swagger' has been removed because it is unmaintained upstream"; # Added 2025-11-10

  musescore-downloader = pkgs.dl-librescore; # added 2023-08-19

  inherit (pkgs) near-cli; # added 2023-09-09

  neovim = pkgs.neovim-node-client; # added 2024-11-13
@@ -247,6 +252,7 @@ mapAliases { 
  parcel-bundler = self.parcel; # added 2023-09-04

  parsoid = throw "The Javascript version of Parsoid has been deprecated by upstream and no longer works with modern MediaWiki versions"; # Added 2025-11-04

  inherit (pkgs) patch-package; # added 2024-06-29

  inherit (pkgs) peerflix-server; # Added 2025-11-10

  pkg = pkgs.vercel-pkg; # added 2023-10-04

  inherit (pkgs) pm2; # added 2024-01-22

  inherit (pkgs) pnpm; # added 2024-06-26
@@ -282,6 +288,7 @@ mapAliases { 
  stf = throw "stf was removed because it was broken"; # added 2023-08-21

  inherit (pkgs) stylelint; # added 2023-09-13

  surge = pkgs.surge-cli; # Added 2023-09-08

  inherit (pkgs) svelte-check; # Added 2025-11-10

  inherit (pkgs) svelte-language-server; # Added 2024-05-12

  inherit (pkgs) svgo; # added 2025-08-24

  swagger = throw "swagger was removed because it was broken and abandoned upstream"; # added 2023-09-09
@@ -345,6 +352,7 @@ mapAliases { 
  thelounge-theme-zenburn-monospace = throw "thelounge-theme-zenburn-monospace has been removed because thelounge was moved out of nodePackages"; # added 2025-03-12

  thelounge-theme-zenburn-sourcecodepro = throw "thelounge-theme-zenburn-sourcecodepro has been removed because thelounge was moved out of nodePackages"; # added 2025-03-12

  three = throw "three was removed because it was no longer needed"; # Added 2023-09-08

  inherit (pkgs) tiddlywiki; # Added 2025-11-10

  triton = pkgs.triton; # Added 2023-05-06

  ts-node = throw "'ts-node' was removed because it is unmaintained, and since NodeJS 22.6.0+, experimental TypeScript support is built-in to NodeJS."; # Added 2025-11-07

  typescript = pkgs.typescript; # Added 2023-06-21