python313Packages.gluonts: init at 0.16.1 (#397419) (7e5b1d19) · Commits · nix / nixpkgs

pkgs/development/python-modules/gluonts/default.nix

0 → 100644

+113 −0

Original line number	Diff line number	Diff line
		{
		stdenv,
		lib,
		buildPythonPackage,
		fetchFromGitHub,
		setuptools,

		# dependencies
		numpy,
		pandas,
		pydantic,
		tqdm,
		toolz,

		# optional dependencies (torch)
		torch,
		lightning,
		scipy,

		# test
		pytestCheckHook,
		distutils,
		matplotlib,
		pyarrow,
		statsmodels,
		which,
		}:

		buildPythonPackage rec {
		pname = "gluonts";
		version = "0.16.1";
		pyproject = true;

		src = fetchFromGitHub {
		owner = "awslabs";
		repo = "gluonts";
		tag = "v${version}";
		hash = "sha256-i4yCNe8C9BZw6AZUDOZC1E9PQOOOoUovSZnOF1yzycM=";
		};

		build-system = [
		setuptools
		];

		dependencies = [
		numpy
		pandas
		pydantic
		tqdm
		toolz
		];

		optional-dependencies = {
		torch = [
		torch
		lightning
		scipy
		];
		};

		pythonRelaxDeps = [
		"numpy"
		"toolz"
		];

		pythonImportsCheck = [
		"gluonts"
		"gluonts.core"
		"gluonts.dataset"
		"gluonts.ev"
		"gluonts.evaluation"
		"gluonts.ext"
		"gluonts.model"
		"gluonts.shell"
		"gluonts.time_feature"
		"gluonts.torch"
		"gluonts.transform"
		];

		nativeCheckInputs = [
		pytestCheckHook
		distutils
		matplotlib
		pyarrow
		statsmodels
		which
		] ++ optional-dependencies.torch;

		preCheck = ''export HOME=$(mktemp -d)'';

		disabledTestPaths = [
		# requires `cpflows`, not in Nixpkgs
		"test/torch/model"
		];

		disabledTests =
		[
		# tries to access network
		"test_against_former_evaluator"
		]
		++ lib.optionals stdenv.hostPlatform.isDarwin [
		# RuntimeError: *** -[__NSPlaceholderArray initWithObjects:count:]: attempt to insert nil object from objects[1]
		"test_forecast"
		];

		meta = {
		description = "Probabilistic time series modeling in Python";
		homepage = "https://ts.gluon.ai";
		changelog = "https://github.com/awslabs/gluonts/releases/tag/${src.tag}";
		license = lib.licenses.asl20;
		maintainers = with lib.maintainers; [ bcdarwin ];
		};
		}

pkgs/development/python-modules/lightning/default.nix

0 → 100644

+43 −0

Original line number	Diff line number	Diff line
		{
		lib,
		buildPythonPackage,
		fetchFromGitHub,

		# build-system
		setuptools,

		# dependencies
		pytorch-lightning,

		# tests
		psutil,
		pytestCheckHook,
		}:

		buildPythonPackage {
		pname = "lightning";
		pyproject = true;

		inherit (pytorch-lightning)
		version
		src
		build-system
		meta
		;

		dependencies = pytorch-lightning.dependencies ++ [ pytorch-lightning ];

		nativeCheckInputs = [
		psutil
		pytestCheckHook
		];

		# Some packages are not in NixPkgs; other tests try to build distributed
		# models, which doesn't work in the sandbox.
		doCheck = false;

		pythonImportsCheck = [
		"lightning"
		"lightning.pytorch"
		];
		}

pkgs/top-level/python-packages.nix

+4 −0

Original line number	Diff line number	Diff line
		@@ -5627,6 +5627,8 @@ self: super: with self; {

		glueviz = callPackage ../development/python-modules/glueviz { };

		gluonts = callPackage ../development/python-modules/gluonts { };

		glymur = callPackage ../development/python-modules/glymur { };

		glyphsets = callPackage ../development/python-modules/glyphsets { };
		@@ -7939,6 +7941,8 @@ self: super: with self; {

		lightify = callPackage ../development/python-modules/lightify { };

		lightning = callPackage ../development/python-modules/lightning { };

		lightning-utilities = callPackage ../development/python-modules/lightning-utilities { };

		lightparam = callPackage ../development/python-modules/lightparam { };