upsies: init at 2025.04.21 (#407500)

{

  lib,

  fetchFromGitea,

  fetchpatch,

  ffmpeg-headless,

  mediainfo,

  oxipng,

  python3Packages,

}:

let

  # Taken from `docker/alpine/Dockerfile`

  runtimeDeps = [

    ffmpeg-headless

    mediainfo

    oxipng

  ];

in

python3Packages.buildPythonApplication rec {

  pname = "upsies";

  version = "2025.04.21";

  pyproject = true;

  src = fetchFromGitea {

    domain = "codeberg.org";

    owner = "plotski";

    repo = "upsies";

    tag = "v${version}";

    hash = "sha256-gjv0HOFV1VdfhVejGbV2+bMxP9BPfB3/3p6nOAYMS34=";

  };

  patches = [

    (fetchpatch {

      name = "use-pytest-timeout.patch";

      url = "https://codeberg.org/plotski/upsies/commit/db6b564f8575c913a6fbabb61d5326a073c9b52c.patch";

      hash = "sha256-UeUrZ6ogUSS0FvyNQwwwp8q+FArEK61o+Y2Uh7mrPtw=";

      revert = true;

    })

  ];

  build-system = with python3Packages; [

    setuptools

  ];

  dependencies = with python3Packages; [

    aiobtclientapi

    async-lru

    beautifulsoup4

    countryguess

    guessit

    httpx

    langcodes

    natsort

    packaging

    prompt-toolkit

    pydantic

    pyimgbox

    pyparsebluray

    pyxdg

    term-image

    torf

    unidecode

  ];

  nativeCheckInputs =

    with python3Packages;

    [

      pytest-asyncio

      pytest-mock

      pytest-timeout

      pytest-httpserver

      pytestCheckHook

      trustme

    ]

    ++ runtimeDeps;

  disabledTestPaths = [

    # DNS resolution errors in the sandbox on some of the tests

    "tests/utils_test/http_test/http_test.py"

    "tests/utils_test/http_test/http_tls_test.py"

  ];

  preCheck = ''

    # `utils.is_running_in_development_environment` expects it in tests

    export VIRTUAL_ENV=1

  '';

  makeWrapperArgs = [

    "--suffix"

    "PATH"

    ":"

    (lib.makeBinPath runtimeDeps)

  ];

  meta = with lib; {

    description = "a toolkit for collecting, generating, normalizing and sharing video metadata";

    homepage = "https://upsies.readthedocs.io/";

    license = with licenses; [ gpl3Plus ];

    mainProgram = "upsies";

    maintainers = with maintainers; [ ambroisie ];

  };

}

{

  lib,

  buildPythonPackage,

  fetchFromGitea,

  aiobtclientrpc,

  async-timeout,

  httpx,

  torf,

  pytest-asyncio,

  pytest-mock,

  pytestCheckHook,

  setuptools,

}:

buildPythonPackage rec {

  pname = "aiobtclientapi";

  version = "1.1.3";

  pyproject = true;

  src = fetchFromGitea {

    domain = "codeberg.org";

    owner = "plotski";

    repo = "aiobtclientapi";

    tag = "v${version}";

    hash = "sha256-ZpUaMsJs1vdVGQOid7aJ+SJKaCbTtHfSw7cOwPTL0ss=";

  };

  pythonRelaxDeps = [

    "async-timeout"

  ];

  build-system = [

    setuptools

  ];

  dependencies = [

    aiobtclientrpc

    async-timeout

    httpx

    torf

  ];

  nativeCheckInputs = [

    pytest-asyncio

    pytest-mock

    pytestCheckHook

  ];

  pythonImportsCheck = [ "aiobtclientapi" ];

  disabledTestPaths = [

    # AttributeError

    "tests/clients_test/rtorrent_test/rtorrent_api_test.py"

  ];

  meta = {

    description = "Asynchronous high-level communication with BitTorrent clients";

    homepage = "https://aiobtclientapi.readthedocs.io";

    license = lib.licenses.gpl3Plus;

    maintainers = with lib.maintainers; [ ambroisie ];

  };

}

{

  lib,

  buildPythonPackage,

  fetchFromGitea,

  async-timeout,

  httpx,

  httpx-socks,

  proxy-py,

  pytest-asyncio,

  pytest-mock,

  pytestCheckHook,

  python-socks,

  rencode,

  setuptools,

}:

buildPythonPackage rec {

  pname = "aiobtclientrpc";

  version = "5.0.1";

  pyproject = true;

  src = fetchFromGitea {

    domain = "codeberg.org";

    owner = "plotski";

    repo = "aiobtclientrpc";

    tag = "v${version}";

    hash = "sha256-2nBrIMlYUI4PwirkiSJSkw5zw2Kc/KoVRyIIYYx4iYs=";

  };

  pythonRelaxDeps = [

    "async-timeout"

  ];

  build-system = [

    setuptools

  ];

  dependencies = [

    async-timeout

    httpx

    httpx-socks

    python-socks

    rencode

  ] ++ python-socks.optional-dependencies.asyncio;

  nativeCheckInputs = [

    proxy-py

    pytest-asyncio

    pytest-mock

    pytestCheckHook

  ];

  disabledTests = [

    # Missing lambda parameter

    "test_add_event_handler_with_autoremove"

    # Try to use `htpasswd` and `nginx` with hard-coded paths

    "test_authentication_error[rtorrent_http]"

    "test_api_as_context_manager[rtorrent_http]"

    "test_add_and_remove_torrents[rtorrent_http-paused]"

    "test_add_and_remove_torrents[rtorrent_http-started]"

    "test_proxy[rtorrent_http-http_proxy]"

    "test_timeout[rtorrent_http]"

    "test_event_subscriptions_survive_reconnecting[rtorrent_http]"

    "test_waiting_for_event[rtorrent_http]"

  ];

  pythonImportsCheck = [ "aiobtclientrpc" ];

  meta = {

    description = "Asynchronous low-level communication with BitTorrent clients";

    homepage = "https://aiobtclientrpc.readthedocs.io";

    license = lib.licenses.gpl3Plus;

    maintainers = with lib.maintainers; [ ambroisie ];

  };

}

{

  lib,

  buildPythonPackage,

  fetchFromGitea,

  pytest-mock,

  pytestCheckHook,

  setuptools,

}:

buildPythonPackage rec {

  pname = "countryguess";

  version = "0.4.5";

  pyproject = true;

  src = fetchFromGitea {

    domain = "codeberg.org";

    owner = "plotski";

    repo = "countryguess";

    tag = "v${version}";

    hash = "sha256-JzhkXHitleQ2UIxdem8PYR5QhKGmkyfHmxG6VDP7pB0=";

  };

  build-system = [

    setuptools

  ];

  nativeCheckInputs = [

    pytest-mock

    pytestCheckHook

  ];

  pythonImportsCheck = [ "countryguess" ];

  meta = {

    description = "Fuzzy lookup of country information";

    homepage = "https://codeberg.org/plotski/countryguess";

    license = lib.licenses.gpl3Plus;

    maintainers = with lib.maintainers; [ ambroisie ];

  };

}

{

  lib,

  buildPythonPackage,

  fetchFromGitHub,

  hypothesis,

  pytestCheckHook,

  setuptools,

}:

buildPythonPackage rec {

  pname = "flatbencode";

  version = "0.2.1";

  pyproject = true;

  src = fetchFromGitHub {

    owner = "acatton";

    repo = "flatbencode";

    tag = "v${version}";

    hash = "sha256-1/4w41E8IKygJTBcQOexiDytV6BvVBwIjajKz2uCfu8=";

  };

  build-system = [

    setuptools

  ];

  nativeCheckInputs = [

    hypothesis

    pytestCheckHook

  ];

  pythonImportsCheck = [ "flatbencode" ];

  meta = {

    description = "Fast, safe and non-recursive implementation of Bittorrent bencoding";

    homepage = "https://github.com/acatton/flatbencode";

    license = lib.licenses.mit;

    maintainers = with lib.maintainers; [ ambroisie ];

  };

}