python3Packages.unsloth: init at 2025.4.1 (#388735)

    githubId = 57007241;

    name = "hogcycle";

  };

  hoh = {

    email = "git@hugoherter.com";

    github = "hoh";

    githubId = 404665;

    name = "Hugo Herter";

  };

  holgerpeters = {

    name = "Holger Peters";

    email = "holger.peters@posteo.de";

{

  lib,

  buildPythonPackage,

  fetchFromGitHub,

  # build-system

  setuptools,

  setuptools-scm,

  # dependencies

  torch,

  triton,

  # optional-dependencies

  accelerate,

  datasets,

  fire,

  huggingface-hub,

  pandas,

  pytestCheckHook,

  pythonAtLeast,

  tqdm,

  transformers,

}:

buildPythonPackage {

  pname = "cut-cross-entropy";

  version = "25.3.1";

  pyproject = true;

  # The `ml-cross-entropy` Pypi comes from a third-party.

  # Apple recommends installing from the repo's main branch directly

  src = fetchFromGitHub {

    owner = "apple";

    repo = "ml-cross-entropy";

    rev = "24fbe4b5dab9a6c250a014573613c1890190536c"; # no tags

    hash = "sha256-BVPon+T7chkpozX/IZU3KZMw1zRzlYVvF/22JWKjT2Y=";

  };

  # Python 3.13 support requires PyTorch 2.6, which is not merged into master yet

  # https://github.com/NixOS/nixpkgs/pull/377785

  disabled = pythonAtLeast "3.13";

  build-system = [

    setuptools

    setuptools-scm

  ];

  dependencies = [

    torch

    triton

  ];

  optional-dependencies = {

    transformers = [ transformers ];

    all = [

      accelerate

      datasets

      fire

      huggingface-hub

      pandas

      tqdm

      transformers

    ];

    # `deepspeed` is not yet packaged in nixpkgs

    # ++ lib.optionals (!stdenv.isDarwin) [

    #   deepspeed

    # ];

  };

  nativeCheckInputs = [ pytestCheckHook ];

  pythonImportsCheck = [

    "cut_cross_entropy"

  ];

  meta = {

    description = "Memory-efficient cross-entropy loss implementation using Cut Cross-Entropy (CCE)";

    homepage = "https://github.com/apple/ml-cross-entropy";

    license = lib.licenses.aml;

    maintainers = with lib.maintainers; [ hoh ];

  };

}

{

  lib,

  buildPythonPackage,

  fetchFromGitHub,

  # build-system

  setuptools,

  setuptools-scm,

  # dependencies

  accelerate,

  datasets,

  rich,

  transformers,

}:

buildPythonPackage rec {

  pname = "trl";

  version = "0.15.2";

  pyproject = true;

  src = fetchFromGitHub {

    owner = "huggingface";

    repo = "trl";

    tag = "v${version}";

    hash = "sha256-HsSmFXFqDOWVLa6VXdPZVS9C3bjYcsliR0TwNpPiQx4=";

  };

  build-system = [

    setuptools

    setuptools-scm

  ];

  dependencies = [

    accelerate

    datasets

    rich

    transformers

  ];

  # Many tests require internet access.

  doCheck = false;

  pythonImportsCheck = [ "trl" ];

  meta = {

    description = "Train transformer language models with reinforcement learning";

    homepage = "https://github.com/huggingface/trl";

    changelog = "https://github.com/huggingface/trl/releases/tag/v${version}";

    license = lib.licenses.asl20;

    maintainers = with lib.maintainers; [ hoh ];

  };

}

{

  lib,

  buildPythonPackage,

  fetchFromGitHub,

  # build-system

  hatchling,

  # dependencies

  docstring-parser,

  rich,

  shtab,

  typeguard,

  typing-extensions,

  # tests

  attrs,

  flax,

  jax,

  ml-collections,

  omegaconf,

  pydantic,

  pytestCheckHook,

  torch,

}:

buildPythonPackage rec {

  pname = "tyro";

  version = "0.9.19";

  pyproject = true;

  src = fetchFromGitHub {

    owner = "brentyi";

    repo = "tyro";

    tag = "v${version}";

    hash = "sha256-A1Vplc84Xy8TufqmklPUzIdgiPpFcIjqV0eUgdKmYRM=";

  };

  build-system = [ hatchling ];

  dependencies = [

    docstring-parser

    rich

    shtab

    typeguard

    typing-extensions

  ];

  nativeCheckInputs = [

    attrs

    flax

    jax

    ml-collections

    omegaconf

    pydantic

    pytestCheckHook

    torch

  ];

  pythonImportsCheck = [ "tyro" ];

  meta = {

    description = "CLI interfaces & config objects, from types";

    homepage = "https://github.com/brentyi/tyro";

    changelog = "https://github.com/brentyi/tyro/releases/tag/v${version}";

    license = lib.licenses.mit;

    maintainers = with lib.maintainers; [ hoh ];

  };

}

{

  lib,

  buildPythonPackage,

  fetchPypi,

  # build-system

  setuptools,

  setuptools-scm,

  # dependencies

  accelerate,

  cut-cross-entropy,

  datasets,

  hf-transfer,

  huggingface-hub,

  packaging,

  peft,

  psutil,

  sentencepiece,

  torch,

  tqdm,

  transformers,

  trl,

  tyro,

}:

buildPythonPackage rec {

  pname = "unsloth-zoo";

  version = "2025.4.1";

  pyproject = true;

  # no tags on GitHub

  src = fetchPypi {

    pname = "unsloth_zoo";

    inherit version;

    hash = "sha256-mRs/NMCNJWT52S7mtbQI332IQR6+/IaL29XmtMOz3fE=";

  };

  # pyproject.toml requires an obsolete version of protobuf,

  # but it is not used.

  # Upstream issue: https://github.com/unslothai/unsloth-zoo/pull/68

  pythonRelaxDeps = [

    "protobuf"

  ];

  patches = [

    # Avoid circular dependency in Nix, since `unsloth` depends on `unsloth-zoo`.

    ./dont-require-unsloth.patch

  ];

  build-system = [

    setuptools

    setuptools-scm

  ];

  dependencies = [

    accelerate

    cut-cross-entropy

    datasets

    hf-transfer

    huggingface-hub

    packaging

    peft

    psutil

    sentencepiece

    torch

    tqdm

    transformers

    trl

    tyro

  ];

  # No tests

  doCheck = false;

  pythonImportsCheck = [

    "unsloth_zoo"

  ];

  meta = {

    description = "Utils for Unsloth";

    homepage = "https://github.com/unslothai/unsloth_zoo";

    license = lib.licenses.mit;

    maintainers = with lib.maintainers; [ hoh ];

  };

}