highscore-nestopia: init at 0-unstable-2025-12-30

{

  lib,

  stdenv,

  fetchFromGitLab,

  meson,

  ninja,

  pkg-config,

  libhighscore,

  unstableGitUpdater,

}:

stdenv.mkDerivation (finalAttrs: {

  pname = "highscore-nestopia";

  version = "0-unstable-2025-12-30";

  src = fetchFromGitLab {

    owner = "highscore-emu";

    repo = "nestopia";

    rev = "529e69b6e577f42a246c8fa44ef7f3095647adaf";

    hash = "sha256-2aBEtut6AShP1Nz0BqNTFD3/gN2cj5PY8JL8WbLE7XE=";

  };

  sourceRoot = "${finalAttrs.src.name}/highscore";

  postPatch = ''

    substituteInPlace meson.build \

      --replace-fail "run_command('git', 'describe', '--always', '--dirty', '--match', ''', check: false).stdout().strip()" \

        "'${finalAttrs.src.rev}'"

  '';

  nativeBuildInputs = [

    meson

    ninja

    pkg-config

  ];

  buildInputs = [

    libhighscore

  ];

  passthru.updateScript = unstableGitUpdater {

    hardcodeZeroVersion = true;

  };

  meta = {

    description = "Port of Nestopia to Highscore";

    homepage = "https://gitlab.com/highscore-emu/nestopia";

    license = lib.licenses.gpl2Plus;

    inherit (libhighscore.meta) maintainers platforms;

  };

})