Commit 62e95d09 authored by nikstur's avatar nikstur
Browse files

nixos/qemu-vm: optionally disable overriding fileSystems 

Allow the user to disable overriding the fileSystems option with
virtualisation.fileSystems by setting
`virtualisation.fileSystems = lib.mkForce { };`.

With this change you can use the qemu-vm module to boot from an external
image that was not produced by the qemu-vm module itself. The user can
now re-use the modularly set fileSystems option instead of having to
reproduce it in virtualisation.fileSystems.
parent f902cb49

nixos/doc/manual/release-notes/rl-2311.section.md

+6 −0
Original line number Diff line number Diff line
@@ -405,4 +405,10 @@ The module update takes care of the new config syntax and the data itself (user 


- `python3.pkgs.flitBuildHook` has been removed. Use `flit-core` and `format = "pyproject"` instead.



- The `qemu-vm.nix` module now supports disabling overriding `fileSystems` with

  `virtualisation.fileSystems`. This enables the user to boot VMs from

  "external" disk images not created by the qemu-vm module. You can stop the

  qemu-vm module from overriding `fileSystems` by setting

  `virtualisation.fileSystems = lib.mkForce { };`.



- The `electron` packages now places its application files in `$out/libexec/electron` instead of `$out/lib/electron`. Packages using electron-builder will fail to build and need to be adjusted by changing `lib` to `libexec`.

nixos/modules/virtualisation/qemu-vm.nix

+6 −5
Original line number Diff line number Diff line
@@ -1121,11 +1121,12 @@ in 
      }) cfg.emptyDiskImages)

    ];



    # Use mkVMOverride to enable building test VMs (e.g. via `nixos-rebuild

    # build-vm`) of a system configuration, where the regular value for the

    # `fileSystems' attribute should be disregarded (since those filesystems

    # don't necessarily exist in the VM).

    fileSystems = mkVMOverride cfg.fileSystems;

    # By default, use mkVMOverride to enable building test VMs (e.g. via

    # `nixos-rebuild build-vm`) of a system configuration, where the regular

    # value for the `fileSystems' attribute should be disregarded (since those

    # filesystems don't necessarily exist in the VM). You can disable this

    # override by setting `virtualisation.fileSystems = lib.mkForce { };`.

    fileSystems = lib.mkIf (cfg.fileSystems != { }) (mkVMOverride cfg.fileSystems);



    virtualisation.fileSystems = let

      mkSharedDir = tag: share:

nixos/tests/all-tests.nix

+1 −0
Original line number Diff line number Diff line
@@ -676,6 +676,7 @@ in { 
  qboot = handleTestOn ["x86_64-linux" "i686-linux"] ./qboot.nix {};

  qemu-vm-restrictnetwork = handleTest ./qemu-vm-restrictnetwork.nix {};

  qemu-vm-volatile-root = runTest ./qemu-vm-volatile-root.nix;

  qemu-vm-external-disk-image = runTest ./qemu-vm-external-disk-image.nix;

  qgis = handleTest ./qgis.nix { qgisPackage = pkgs.qgis; };

  qgis-ltr = handleTest ./qgis.nix { qgisPackage = pkgs.qgis-ltr; };

  qownnotes = handleTest ./qownnotes.nix {};

nixos/tests/qemu-vm-external-disk-image.nix

0 → 100644
+73 −0
Original line number Diff line number Diff line 
# Tests that you can boot from an external disk image with the qemu-vm module.

# "External" here means that the image was not produced within the qemu-vm

# module and relies on the fileSystems option also set outside the qemu-vm

# module. Most notably, this tests that you can stop the qemu-vm module from

# overriding fileSystems with virtualisation.fileSystems so you don't have to

# replicate the previously set fileSystems in virtualisation.fileSystems.



{ lib, ... }:



let

  rootFslabel = "external";

  rootFsDevice = "/dev/disk/by-label/${rootFslabel}";



  externalModule = { config, lib, pkgs, ... }: {

    boot.loader.systemd-boot.enable = true;



    fileSystems = {

      "/".device = rootFsDevice;

    };



    system.build.diskImage = import ../lib/make-disk-image.nix {

      inherit config lib pkgs;

      label = rootFslabel;

      partitionTableType = "efi";

      format = "qcow2";

      bootSize = "32M";

      additionalSpace = "0M";

      copyChannel = false;

    };

  };

in

{

  name = "qemu-vm-external-disk-image";



  meta.maintainers = with lib.maintainers; [ nikstur ];



  nodes.machine = { config, lib, pkgs, ... }: {

    virtualisation.directBoot.enable = false;

    virtualisation.mountHostNixStore = false;

    virtualisation.useEFIBoot = true;



    # This stops the qemu-vm module from overriding the fileSystems option

    # with virtualisation.fileSystems.

    virtualisation.fileSystems = lib.mkForce { };



    imports = [ externalModule ];

  };



  testScript = { nodes, ... }: ''

    import os

    import subprocess

    import tempfile



    tmp_disk_image = tempfile.NamedTemporaryFile()



    subprocess.run([

      "${nodes.machine.virtualisation.qemu.package}/bin/qemu-img",

      "create",

      "-f",

      "qcow2",

      "-b",

      "${nodes.machine.system.build.diskImage}/nixos.qcow2",

      "-F",

      "qcow2",

      tmp_disk_image.name,

    ])



    # Set NIX_DISK_IMAGE so that the qemu script finds the right disk image.

    os.environ['NIX_DISK_IMAGE'] = tmp_disk_image.name



    machine.succeed("findmnt --kernel --source ${rootFsDevice} --target /")

  '';

}