igvm-tooling: remove (#458452)

{

  lib,

  python3,

  fetchFromGitHub,

  fetchpatch,

  which,

  acpica-tools,

  unstableGitUpdater,

}:

python3.pkgs.buildPythonApplication rec {

  pname = "igvm-tooling";

  version = "1.5.0-unstable-2024-06-06";

  pyproject = true;

  src = fetchFromGitHub {

    owner = "microsoft";

    repo = "igvm-tooling";

    rev = "53656ddde294bbafcae6349b5acfc5da9f7dbb92";

    hash = "sha256-X9Gi+kTmc/ZcsgbHldEj9zPnOmd5puDD7/+J1s1CVws=";

  };

  patches = [

    # drop unused libclang dependency

    # remove once https://github.com/microsoft/igvm-tooling/pull/53 is merged

    (fetchpatch {

      name = "0001-setup.py-remove-unused-libclang-dependency.patch";

      url = "https://github.com/microsoft/igvm-tooling/commit/7182e925de9b5e9f5c8c3a3ce6e3942a92506064.patch";

      hash = "sha256-tcVxcuLxknyEdo2YjeHOqSG9xQna8US+YyvlcfX+Htw=";

      stripLen = 1;

    })

  ];

  postPatch = ''

    substituteInPlace igvm/acpi.py \

      --replace-fail 'os.path.join(os.path.dirname(__file__), "acpi", "acpi.zip")' "\"$out/share/igvm-tooling/acpi/acpi.zip\""

  '';

  sourceRoot = "${src.name}/src";

  nativeBuildInputs = [ acpica-tools ];

  propagatedBuildInputs =

    (with python3.pkgs; [

      setuptools

      ecdsa

      cstruct

      pyelftools

      pytest

      cached-property

      frozendict

    ])

    ++ [

      acpica-tools

      which

    ];

  postInstall = ''

    mkdir -p $out/share/igvm-tooling/acpi/acpi-clh

    cp -rT igvm/acpi/acpi-clh $out/share/igvm-tooling/acpi/acpi-clh

    cp igvm/acpi/acpi.zip $out/share/igvm-tooling/acpi/acpi.zip

    find $out/share/igvm-tooling/acpi -name "*.dsl" -exec iasl -f {} \;

  '';

  passthru.updateScript = unstableGitUpdater {

    tagPrefix = "igvm-";

  };

  meta = {

    description = "IGVM Image Generator";

    homepage = "https://github.com/microsoft/igvm-tooling";

    license = lib.licenses.mit;

    maintainers = with lib.maintainers; [

      malt3

      katexochen

    ];

    changelog = "https://github.com/microsoft/igvm-tooling/releases/tag/igvm-${version}";

    mainProgram = "igvmgen";

    platforms = lib.platforms.all;

  };

}

  hydra_unstable = throw "'hydra_unstable' has been renamed to/replaced by 'hydra'"; # Converted to throw 2025-10-27

  i3-gaps = throw "'i3-gaps' has been renamed to/replaced by 'i3'"; # Converted to throw 2025-10-27

  ibm-sw-tpm2 = throw "ibm-sw-tpm2 has been removed, as it was broken"; # Added 2025-08-25

  igvm-tooling = throw "'igvm-tooling' has been removed as it is poorly maintained upstream and a dependency has been marked insecure."; # Added 2025-09-03

  ikos = throw "ikos has been removed, as it does not build with supported LLVM versions"; # Added 2025-08-10

  imaginer = throw "'imaginer' has been removed due to lack of upstream maintenance"; # Added 2025-08-15

  immersed-vr = throw "'immersed-vr' has been renamed to/replaced by 'immersed'"; # Converted to throw 2025-10-27