Unverified Commit 5496585e authored by Stanisław Pitucha's avatar Stanisław Pitucha Committed by GitHub
Browse files

Merge pull request #186076 from viraptor/gemstash-service 

nixos/gemstash: init module
parents e9cf2d1a 70073985

nixos/doc/manual/release-notes/rl-2305.section.md

+2 −0
Original line number Diff line number Diff line
@@ -34,6 +34,8 @@ In addition to numerous new and upgraded packages, this release has the followin 


- [fzf](https://github.com/junegunn/fzf), a command line fuzzyfinder. Available as [programs.fzf](#opt-programs.fzf.fuzzyCompletion).



- [gemstash](https://github.com/rubygems/gemstash), a RubyGems.org cache and private gem server. Available as [services.gemstash](#opt-services.gemstash.enable).



- [gmediarender](https://github.com/hzeller/gmrender-resurrect), a simple, headless UPnP/DLNA renderer.  Available as [services.gmediarender](options.html#opt-services.gmediarender.enable).



- [stevenblack-blocklist](https://github.com/StevenBlack/hosts), A unified hosts file with base extensions for blocking unwanted websites. Available as [networking.stevenblack](options.html#opt-networking.stevenblack.enable).

nixos/modules/module-list.nix

+1 −0
Original line number Diff line number Diff line
@@ -440,6 +440,7 @@ 
  ./services/development/blackfire.nix

  ./services/development/bloop.nix

  ./services/development/distccd.nix

  ./services/development/gemstash.nix

  ./services/development/hoogle.nix

  ./services/development/jupyter/default.nix

  ./services/development/jupyterhub/default.nix

nixos/modules/services/development/gemstash.nix

0 → 100644
+103 −0
Original line number Diff line number Diff line 
{ lib, pkgs, config, ... }:

with lib;



let

  settingsFormat = pkgs.formats.yaml { };



  # gemstash uses a yaml config where the keys are ruby symbols,

  # which means they start with ':'. This would be annoying to use

  # on the nix side, so we rewrite plain names instead.

  prefixColon = s: listToAttrs (map

    (attrName: {

      name = ":${attrName}";

      value =

        if isAttrs s.${attrName}

        then prefixColon s."${attrName}"

        else s."${attrName}";

    })

    (attrNames s));



  # parse the port number out of the tcp://ip:port bind setting string

  parseBindPort = bind: strings.toInt (last (strings.splitString ":" bind));



  cfg = config.services.gemstash;

in

{

  options.services.gemstash = {

    enable = mkEnableOption (lib.mdDoc "gemstash service");



    openFirewall = mkOption {

      type = types.bool;

      default = false;

      description = lib.mdDoc ''

        Whether to open the firewall for the port in {option}`services.gemstash.bind`.

      '';

    };



    settings = mkOption {

      default = {};

      description = lib.mdDoc ''

        Configuration for Gemstash. The details can be found at in

        [gemstash documentation](https://github.com/rubygems/gemstash/blob/master/man/gemstash-configuration.5.md).

        Each key set here is automatically prefixed with ":" to match the gemstash expectations.

      '';

      type = types.submodule {

        freeformType = settingsFormat.type;

        options = {

          base_path = mkOption {

            type = types.path;

            default = "/var/lib/gemstash";

            description = lib.mdDoc "Path to store the gem files and the sqlite database. If left unchanged, the directory will be created.";

          };

          bind = mkOption {

            type = types.str;

            default = "tcp://0.0.0.0:9292";

            description = lib.mdDoc "Host and port combination for the server to listen on.";

          };

          db_adapter = mkOption {

            type = types.nullOr (types.enum [ "sqlite3" "postgres" "mysql" "mysql2" ]);

            default = null;

            description = lib.mdDoc "Which database type to use. For choices other than sqlite3, the dbUrl has to be specified as well.";

          };

          db_url = mkOption {

            type = types.nullOr types.str;

            default = null;

            description = lib.mdDoc "The database to connect to when using postgres, mysql, or mysql2.";

          };

        };

      };

    };

  };



  config =

    mkIf cfg.enable {

      users = {

        users.gemstash = {

          group = "gemstash";

          isSystemUser = true;

        };

        groups.gemstash = { };

      };



      networking.firewall.allowedTCPPorts = mkIf cfg.openFirewall [ (parseBindPort cfg.settings.bind) ];



      systemd.services.gemstash = {

        wantedBy = [ "multi-user.target" ];

        after = [ "network.target" ];

        serviceConfig = mkMerge [

          {

            ExecStart = "${pkgs.gemstash}/bin/gemstash start --no-daemonize --config-file ${settingsFormat.generate "gemstash.yaml" (prefixColon cfg.settings)}";

            NoNewPrivileges = true;

            User = "gemstash";

            Group = "gemstash";

            PrivateTmp = true;

            RestrictSUIDSGID = true;

            LockPersonality = true;

          }

          (mkIf (cfg.settings.base_path == "/var/lib/gemstash") {

            StateDirectory = "gemstash";

          })

        ];

      };

    };

}

nixos/tests/all-tests.nix

+1 −0
Original line number Diff line number Diff line
@@ -239,6 +239,7 @@ in { 
  ft2-clone = handleTest ./ft2-clone.nix {};

  mimir = handleTest ./mimir.nix {};

  garage = handleTest ./garage {};

  gemstash = handleTest ./gemstash.nix {};

  gerrit = handleTest ./gerrit.nix {};

  geth = handleTest ./geth.nix {};

  ghostunnel = handleTest ./ghostunnel.nix {};

nixos/tests/gemstash.nix

0 → 100644
+51 −0
Original line number Diff line number Diff line 
{ system ? builtins.currentSystem, config ? { }

, pkgs ? import ../.. { inherit system config; } }:



with import ../lib/testing-python.nix { inherit system pkgs; };

with pkgs.lib;



let common_meta = { maintainers = [ maintainers.viraptor ]; };

in

{

  gemstash_works = makeTest {

    name = "gemstash-works";

    meta = common_meta;



    nodes.machine = { config, pkgs, ... }: {

      services.gemstash = {

        enable = true;

      };

    };



    # gemstash responds to http requests

    testScript = ''

      machine.wait_for_unit("gemstash.service")

      machine.wait_for_file("/var/lib/gemstash")

      machine.wait_for_open_port(9292)

      machine.succeed("curl http://localhost:9292")

    '';

  };



  gemstash_custom_port = makeTest {

    name = "gemstash-custom-port";

    meta = common_meta;



    nodes.machine = { config, pkgs, ... }: {

      services.gemstash = {

        enable = true;

        openFirewall = true;

        settings = {

          bind = "tcp://0.0.0.0:12345";

        };

      };

    };



    # gemstash responds to http requests

    testScript = ''

      machine.wait_for_unit("gemstash.service")

      machine.wait_for_file("/var/lib/gemstash")

      machine.wait_for_open_port(12345)

      machine.succeed("curl http://localhost:12345")

    '';

  };

}