Merge pull request #300265 from anthonyroussel/update/httpdirfs (4d321931) · Commits · nix / nixpkgs

pkgs/by-name/ht/httpdirfs/package.nix

0 → 100644

+70 −0

Original line number	Diff line number	Diff line
		{
		curl,
		expat,
		fetchFromGitHub,
		fuse,
		gumbo,
		help2man,
		lib,
		libuuid,
		nix-update-script,
		pkg-config,
		stdenv,
		testers,
		}:

		stdenv.mkDerivation (finalAttrs: {
		pname = "httpdirfs";
		version = "1.2.5";

		src = fetchFromGitHub {
		owner = "fangfufu";
		repo = "httpdirfs";
		rev = "refs/tags/${finalAttrs.version}";
		sha256 = "sha256-PUYsT0VDEzerPqwrLJrET4kSsWsQhtnfmLepeaqtA+I=";
		};

		postPatch = lib.optional stdenv.isDarwin ''
		substituteInPlace Makefile --replace-fail '-fanalyzer' '-Xanalyzer'
		'';

		nativeBuildInputs = [
		help2man
		pkg-config
		];

		buildInputs = [
		curl
		expat
		fuse
		gumbo
		libuuid
		];

		makeFlags = [ "prefix=${placeholder "out"}" ];

		postBuild = ''
		make man
		'';

		passthru = {
		# Disabled for Darwin because requires macFUSE installed outside NixOS
		tests.version = lib.optionalAttrs stdenv.isLinux (
		testers.testVersion {
		command = "${lib.getExe finalAttrs.finalPackage} --version";
		package = finalAttrs.finalPackage;
		}
		);
		updateScript = nix-update-script { };
		};

		meta = {
		changelog = "https://github.com/fangfufu/httpdirfs/releases/tag/${finalAttrs.version}";
		description = "A FUSE filesystem for HTTP directory listings";
		homepage = "https://github.com/fangfufu/httpdirfs";
		license = lib.licenses.gpl3Only;
		mainProgram = "httpdirfs";
		maintainers = with lib.maintainers; [ sbruder schnusch anthonyroussel ];
		platforms = lib.platforms.unix;
		};
		})

deleted100644 → 0

+0 −27

Original line number	Diff line number	Diff line
		{ lib, stdenv, fetchFromGitHub, pkg-config, curl, expat, fuse, gumbo, libuuid }:

		stdenv.mkDerivation rec {
		pname = "httpdirfs";
		version = "1.2.3";

		src = fetchFromGitHub {
		owner = "fangfufu";
		repo = pname;
		rev = version;
		sha256 = "sha256-rdeBlAV3t/si9x488tirUGLZRYAxh13zdRIQe0OPd+A=";
		};

		nativeBuildInputs = [ pkg-config ];
		buildInputs = [ curl expat fuse gumbo libuuid ];

		makeFlags = [ "prefix=${placeholder "out"}" ];

		meta = with lib; {
		description = "A FUSE filesystem for HTTP directory listings";
		homepage = "https://github.com/fangfufu/httpdirfs";
		license = licenses.gpl3Only;
		maintainers = with maintainers; [ sbruder schnusch ];
		platforms = platforms.unix;
		mainProgram = "httpdirfs";
		};
		}

+0 −2

Original line number	Diff line number	Diff line
		@@ -9142,8 +9142,6 @@ with pkgs;

		http-getter = callPackage ../applications/networking/flent/http-getter.nix { };

		httpdirfs = callPackage ../tools/filesystems/httpdirfs { };

		httpdump = callPackage ../tools/security/httpdump { };

		httpie = with python3Packages; toPythonApplication httpie;