libfoundry: init at 1.0.1

diff --git a/plugins/fallbacks/host-sdk/plugin-host-sdk.c b/plugins/fallbacks/host-sdk/plugin-host-sdk.c

index d3deb4fd..98ea0875 100644

--- a/plugins/fallbacks/host-sdk/plugin-host-sdk.c

+++ b/plugins/fallbacks/host-sdk/plugin-host-sdk.c

@@ -111,5 +111,11 @@ plugin_host_sdk_build_filename (PluginHostSdk  *self,

   if (g_path_is_absolute (joined))

     return g_steal_pointer (&joined);

+  if (g_strcmp0(g_get_os_info(G_OS_INFO_KEY_NAME), "NixOS") == 0) {

+    GString *str = g_string_new(joined);

+    g_string_replace(str, "usr/share", "run/current-system/sw/share", 0);

+    joined = g_string_free(str, FALSE);

+  }

+

   return g_build_filename ("/", joined, NULL);

 }

{

  stdenv,

  lib,

  cmark,

  editorconfig-core-c,

  fetchurl,

  flatpak,

  gi-docgen,

  glib,

  gnome,

  gobject-introspection,

  gom,

  gtk4,

  gtksourceview5,

  json-glib,

  libdex,

  libgit2,

  libpeas2,

  libsoup_3,

  libspelling,

  libssh2,

  libsysprof-capture,

  libxml2,

  libyaml,

  meson,

  ninja,

  pkg-config,

  template-glib,

  vte-gtk4,

  webkitgtk_6_0,

  wrapGAppsNoGuiHook,

  withGtk ? true,

}:

stdenv.mkDerivation (finalAttrs: {

  pname = "libfoundry${lib.optionalString withGtk "-gtk"}";

  version = "1.0.1";

  outputs = [

    "out"

    "dev"

    "devdoc"

  ];

  src = fetchurl {

    url = "mirror://gnome/sources/foundry/${lib.versions.majorMinor finalAttrs.version}/foundry-${finalAttrs.version}.tar.xz";

    hash = "sha256-wHaJBv6zTdWBmeKFRHOeohe714g+WPJPEjIphryJkzk=";

  };

  patches = [

    ./host_sdk_filename_nixos.patch

  ];

  nativeBuildInputs = [

    gi-docgen

    gobject-introspection

    meson

    ninja

    pkg-config

    wrapGAppsNoGuiHook

  ];

  buildInputs = [

    editorconfig-core-c

    flatpak

    gom

    libgit2

    libsoup_3

    libssh2

    libsysprof-capture

    libxml2

    libyaml

    template-glib

  ]

  ++ lib.optionals withGtk [

    cmark

    gtk4

    gtksourceview5

    libspelling

    vte-gtk4

    webkitgtk_6_0

  ];

  propagatedBuildInputs = [

    glib

    json-glib

    libdex

    libpeas2

  ];

  strictDeps = true;

  mesonFlags = [

    (lib.mesonBool "docs" true)

    (lib.mesonBool "gtk" withGtk)

  ];

  postFixup = ''

    # Cannot be in postInstall, otherwise _multioutDocs hook in preFixup will move right back.

    moveToOutput "share/doc" "$devdoc"

  '';

  passthru.updateScript = gnome.updateScript {

    packageName = "foundry";

    attrPath = "libfoundry";

  };

  meta = {

    description = "Command line tool and library that can be used to build developer tools";

    mainProgram = "foundry";

    homepage = "https://gitlab.gnome.org/GNOME/foundry";

    changelog = "https://gitlab.gnome.org/GNOME/foundry/-/blob/${finalAttrs.version}/NEWS?ref_type=tags";

    license = lib.licenses.lgpl21Plus;

    teams = [ lib.teams.gnome ];

    platforms = lib.platforms.linux;

  };

})