sampo: init at 0.12.0 (#455414)

{

  lib,

  rustPlatform,

  fetchFromGitHub,

  versionCheckHook,

  nix-update-script,

  pkg-config,

  openssl,

}:

rustPlatform.buildRustPackage (finalAttrs: {

  pname = "sampo";

  version = "0.12.0";

  src = fetchFromGitHub {

    owner = "bruits";

    repo = "sampo";

    tag = "sampo-v${finalAttrs.version}";

    hash = "sha256-0E9dvyu6mGbuMH8Lf/rVTn3skVq9kaVjQG2eLH8a2IY=";

  };

  nativeBuildInputs = [ pkg-config ];

  buildInputs = [ openssl ];

  cargoHash = "sha256-gooShQWJY9UKYq99o7qhyz6ROK+VXYG2PpygdVWG0iM=";

  cargoBuildFlags = [

    "-p"

    "sampo"

  ];

  cargoTestFlags = finalAttrs.cargoBuildFlags;

  env.OPENSSL_NO_VENDOR = true;

  nativeInstallCheckInputs = [ versionCheckHook ];

  doInstallCheck = true;

  versionCheckProgramArg = "--version";

  passthru.updateScript = nix-update-script { };

  meta = {

    description = "Automate changelogs, versioning, and publishing—even for monorepos across multiple package registries";

    homepage = "https://github.com/bruits/sampo";

    changelog = "https://github.com/bruits/sampo/blob/sampo-v${finalAttrs.version}/crates/sampo/CHANGELOG.md";

    license = lib.licenses.mit;

    maintainers = with lib.maintainers; [ nartsiss ];

    mainProgram = "sampo";

  };

})