taze: init at 18.6.0 (#385729)

{

  lib,

  stdenv,

  fetchFromGitHub,

  nodejs,

  pnpm_9,

  npmHooks,

  versionCheckHook,

  nix-update-script,

}:

let

  pnpm = pnpm_9;

in

stdenv.mkDerivation (finalAttrs: {

  pname = "taze";

  version = "18.6.0";

  src = fetchFromGitHub {

    owner = "antfu-collective";

    repo = "taze";

    tag = "v${finalAttrs.version}";

    hash = "sha256-IHWDBX2j+HQ77gGLcUBxywDbN6jHEVxT+x6ojWKPr3I=";

  };

  pnpmDeps = pnpm.fetchDeps {

    inherit (finalAttrs) pname version src;

    hash = "sha256-dlGW5WQMctVoVWLd+MnnNlmSh/MRxwcnlkCb5Dm7qsU=";

  };

  nativeBuildInputs = [

    nodejs

    pnpm.configHook

    npmHooks.npmInstallHook

  ];

  buildPhase = ''

    runHook preBuild

    pnpm run build

    find dist -type f \( -name '*.cjs' -or -name '*.cts' -or -name '*.ts' \) -delete

    runHook postBuild

  '';

  dontNpmPrune = true;

  nativeInstallCheckInputs = [

    versionCheckHook

  ];

  versionCheckProgramArg = [ "--version" ];

  doInstallCheck = true;

  passthru.updateScript = nix-update-script { };

  meta = {

    description = "Modern cli tool that keeps your deps fresh";

    homepage = "https://github.com/antfu-collective/taze";

    changelog = "https://github.com/antfu-collective/taze/releases/tag/v${finalAttrs.version}";

    license = lib.licenses.mit;

    maintainers = with lib.maintainers; [ xiaoxiangmoe ];

    mainProgram = "taze";

  };

})