python312Packages.modern-colorthief: init at 0.1.7

{

  lib,

  buildPythonPackage,

  colorthief,

  fetchFromGitHub,

  nix-update-script,

  pillow,

  pytestCheckHook,

  rustPlatform,

}:

buildPythonPackage rec {

  pname = "modern-colorthief";

  version = "0.1.7";

  pyproject = true;

  src = fetchFromGitHub {

    owner = "baseplate-admin";

    repo = "modern_colorthief";

    tag = version;

    hash = "sha256-tALF9EIBTyVi3Ca4kQl9x+V12gjr0xH9OOmuoToxuJA=";

  };

  cargoDeps = rustPlatform.fetchCargoVendor {

    inherit pname version src;

    hash = "sha256-DldfoDpE7epb99Huq0RXkS3cAw0RtIzdWvr9OuZRZTI=";

  };

  nativeBuildInputs = [

    rustPlatform.cargoSetupHook

    rustPlatform.maturinBuildHook

  ];

  optional-dependencies = {

    test = [

      colorthief

      pillow

    ];

  };

  nativeCheckInputs = [ pytestCheckHook ] ++ lib.attrValues optional-dependencies;

  disabledTestPaths = [

    # Requires `fast_colorthief`, which isn't packaged

    "examples/test_time.py"

  ];

  pythonImportsCheck = [ "modern_colorthief" ];

  passthru = {

    updateScript = nix-update-script { };

  };

  meta = {

    homepage = "https://modern-colorthief.readthedocs.io/";

    changelog = "https://github.com/baseplate-admin/modern_colorthief/releases/tag/${src.tag}";

    license = lib.licenses.mit;

    maintainers = with lib.maintainers; [ getchoo ];

  };

}

  modeled = callPackage ../development/python-modules/modeled { };

  modern-colorthief = callPackage ../development/python-modules/modern-colorthief { };

  moderngl = callPackage ../development/python-modules/moderngl { };

  moderngl-window = callPackage ../development/python-modules/moderngl-window { };